TSaveTextFileDialog和Vcl样式

Question

我在Delphi中使用TSaveTextFileDialog组件，但是当Vcl样式启用时，编码组合框将使用当前的vcl样式绘制。

​

​

如何解决这个问题，我的意思是禁用组合框的vcl样式？

Answer 1

TOpenTextFileDialog组件的父类( TSaveTextFileDialog )添加一组Vcl组件来实现Encodings和EncodingIndex属性，您可以使用StyleElements属性在这些Vcl控件上禁用Vcl样式。不幸的是，这些组件是私有的，因此您需要进行一些黑客操作，以获得访问权限并禁用Vcl样式。

这里你有两个选择。

使用类助手。

您可以引入一个帮助函数来获取Panel组件，该组件包含对话框的Vcl控件。

type
 TOpenTextFileDialogHelper=class helper for TOpenTextFileDialog
  function GetPanel : TPanel;
 end;

function TOpenTextFileDialogHelper.GetPanel: TPanel;
begin
  Result:=Self.FPanel;
end;

然后可以编写一个方法来禁用Vcl样式，如下所示：

procedure DisableVclStyles(const Control : TControl);
var
  i : Integer;
begin
  if Control=nil then
    Exit;
   Control.StyleElements:=[];

  if Control is TWinControl then
    for i := 0 to TWinControl(Control).ControlCount-1 do
      DisableVclStyles(TWinControl(Control).Controls[i]);
end;

最后用在这种方式上

  DisableVclStyles(SaveTextFileDialog1.GetPanel);
  SaveTextFileDialog1.Execute;

RTTI

另一个选项是使用RTTI访问私有Vcl组件。

var
  LRttiContext : TRttiContext;
  LRttiField :TRttiField;
begin
  LRttiContext:=TRttiContext.Create;
  for LRttiField in LRttiContext.GetType(SaveTextFileDialog1.ClassType).GetFields do
   if LRttiField.FieldType.IsInstance and LRttiField.FieldType.AsInstance.MetaclassType.ClassNameIs('TPanel') then
    DisableVclStyles(TPanel(LRttiField.GetValue(SaveTextFileDialog1).AsObject));

  SaveTextFileDialog1.Execute;
end;