软件安装脚本

Question

下面的脚本有问题，我们希望使用它作为登录脚本的一部分，以检查软件是否已经安装，如果没有安装，则安装它：

:STEP1
for /f "delims= " %%a in (C:\software-dist.txt) do (
if "%%a"=="Softwarename1" goto STEP2
)
\\server\share\software1.exe
echo Softwarename1 >> C:\software-dist.txt

:STEP2
for /f "delims= " %%a in (C:\software-dist.txt) do (
if "%%a"=="Software name 2" goto END
)
\\server\share\software2.exe /Q
echo Software name 2 >> C:\software-dist.txt

:END

代码是STEP1工作得很好这里软件的名称是一个单词STEP1但是，STEP2中的代码不起作用-在这里，软件的名称被写成三个单独的单词“软件名称2”(每个单词之间有一个空格)。每次运行脚本时，c：\Software-dis.txt将被更新为另一行"Software 2“。

你知道我做错了什么吗？

Answer 1

lc在他的评论中指出了这个问题，但没有明确提供明显的解决办法。

您正在将令牌分隔符设置为空格。您需要使用"DELIMS="禁用DELIMS选项。

for /f "delims=" %%a in (C:\software-dist.txt) do ...

此外，您的ECHO语句在末尾有一个额外的空间，在以后的其他运行中测试它时，这将导致该行不匹配。如果移除空间，则将2作为stderr的句柄处理。一个解决办法是添加括号。

(echo Software name 2) >> C:\software-dist.txt

但有一个更简单、更快的解决方案。可以使用FINDSTR确定文件中是否存在特定行。

:Step1
>nul findstr /xc:"Softwarename1" "C:\software-dist.txt" || (
  "\\server\share\%%F"
  >>"C:\software-dist.txt%" echo Softwarename1
)

:Step2
>nul findstr /xc:"Software name 2" "C:\software-dist.txt" || (
  "\\server\share\%%F"
  >>"C:\software-dist.txt%" echo Software name 2
)

通过添加变量和FOR循环，代码更短、更易于维护。

set "file=C:\software-dist.txt"
for %%F in ("Softwarename1" "Software name 2") do (
  >nul findstr /xc:%%F "%file%" || (
    "\\server\share\%%~F"
    (echo %%~F)>>"%file%"
  )
)