首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >批函数参数中具有特殊特征的奇怪行为?

问批函数参数中具有特殊特征的奇怪行为?
EN

Stack Overflow用户
提问于 2012-09-29 18:58:30
回答 2查看 3.9K关注 0票数 7

假设您运行test.bat "blabla,blabla,^>blabla", "blaby"

test.bat实现:

代码语言:javascript
复制
@SETLOCAL
@ECHO OFF
SET list=%~1
ECHO "LIST: %list%"
ECHO "ARG 1: %~1"
ECHO "ARG 2: %~2"
@ENDLOCAL   
@GOTO :EOF

产出与预期相符:

代码语言:javascript
复制
"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

但是,如果您在批处理文件中使test.bat成为一个函数,该怎么办:

代码语言:javascript
复制
@SETLOCAL
CALL :TEST "blabla,blabla,^>blabla", "blaby"
@ENDLOCAL
@GOTO :EOF

:TEST
@SETLOCAL
@ECHO OFF
SET list=%~1
ECHO "LIST: %list%"
ECHO "ARG 1: %~1"
ECHO "ARG 2: %~2"
@ENDLOCAL   
@GOTO :EOF

在运行它之后,输出是:

代码语言:javascript
复制
"LIST: blabla,blabla,^"
"ARG 1: blabla,blabla,^^>blabla"
"ARG 2: blaby"

哈?

  1. blabla在名单上去了哪里?
  2. ARG 1有^^?为什么?

有人能解释特殊字符在函数参数中的行为与命令行参数的不同吗?

EN

回答 2

Stack Overflow用户

回答已采纳

发布于 2012-09-29 21:50:36

只需使用以下命令,就可以在第一批脚本中获得相同的结果:

代码语言:javascript
复制
call test.bat "blabla,blabla,^>blabla", "blaby"

您的问题来自批处理分析调用语句的一个不幸的方面。它被描述在第六阶段在How does the Windows Command Interpreter (CMD.EXE) parse scripts?。

哎哟-我以为我之前就明白了,但显然不是。为了回应jeb的评论,我对下面的讨论进行了大量编辑。

CMD.EXE的设计者希望有一个像call echo ^^这样的语句来给出与echo ^^相同的结果。在处理特殊字符的阶段2中,这两个语句将^^还原为^。但是CALL语句必须第二次通过第一阶段和第二阶段。因此,在幕后,当CMD.EXE识别阶段6中的CALL语句时,它将剩下的插入符号加倍返回到^^,然后第二轮的阶段2将其还原为^。这两个语句都与屏幕上的单个插入符号相呼应。

不幸的是,CMD.EXE盲目地加倍所有插入符号,即使它们被引用。但是引用的插入符不被视为一种转义,它是一个文字。插入符号不再被消耗。非常不幸。

在解析器的第6阶段,运行call test.bat "blabla,blabla,^>blabla", "blaby"就变成了call test.bat "blabla,blabla,^^>blabla" "blaby"。

这很容易解释为什么ARG 1在输出中看起来是这样的。

至于blabla到哪里去了?,这只是有点棘手。

当脚本执行SET list=%~1时,将移除引号,将^^视为转义插入符,这将减少为^,而>不再转义。因此,SET语句的输出被重定向到"blabla“文件。当然,SET没有输出,所以您的硬盘上应该有一个零长度的"blabla“文件。

编辑--如何使用“迟扩展”正确传递所需的参数

在他的回答中,达沃试图在所谓的例程内扭转插入符号加倍的效果。但是,这是不可靠的,因为您无法确切地知道插入符号可能加倍了多少次。最好是让呼叫者调整呼叫以进行补偿。这很棘手--你必须使用杰布所说的“后期扩张”。

在批处理脚本中,可以定义一个包含所需参数字符串的变量,然后通过使用另一个%转义%,将展开延迟到插入符号加倍之后。您需要将语句中的每个调用的百分比加倍。

代码语言:javascript
复制
@echo off
setlocal
set arg1="blabla,blabla,^>blabla"
call :TEST %%arg1%% "blaby"
echo(
call call :TEST %%%%arg1%%%% "blaby"
::unquoted test
exit /b

:TEST
setlocal
set list=%~1
echo "LIST: %list%"
echo "ARG 1: %~1"
echo "ARG 2: %~2"
exit /b

上述结果产生了预期的结果:

代码语言:javascript
复制
"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

从命令行运行时,展开规则是不同的。从命令行逃出%是不可能的。相反,您必须在百分比中添加一个插入符号,以防止扩展阶段在第一次传递时识别名称,然后当插入符号在第二阶段被剥离时,第二次扩展正确地扩展变量。

以下使用davor的原始TEST.BAT

代码语言:javascript
复制
C:\test>test.bat "blabla,blabla,^>blabla" "blaby"
"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

C:\test>set arg1="blabla,blabla,^>blabla"

C:\test>test.bat %arg1% "blaby"
"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

C:\test>call test.bat %^arg1% "blaby"
"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

C:\test>set arg2=%^arg1%

C:\test>call call test.bat %^arg2% "blaby"
"LIST: blabla,blabla,>blabla"
"ARG 1: blabla,blabla,^>blabla"
"ARG 2: blaby"

-引用转义传递值的替代方案!

总之,逃逸规则是非常复杂的。这就是为什么高级批处理脚本经常通过引用而不是文字传递字符串值的原因。所需的字符串放置在变量中,然后将变量的名称作为参数传递。延迟扩展是用来获得准确的字符串,而不担心由于特殊字符或调用插入符号加倍或百分比剥离。

下面是一个简单的test.bat,它演示了这个概念

代码语言:javascript
复制
@echo off
setlocal enableDelayedExpansion
set "var1=!%~1!"
echo var1=!var1!

call :test var1
exit /b

:test
set "var2=!%~1!"
echo var2=!var2!

这里展示了它的工作原理。

代码语言:javascript
复制
C:\test>set complicatedString="This & that ^" ^& the other thing ^^ is 100% difficult to escape

C:\test>set complicatedString
complicatedString="This & that ^" & the other thing ^ is 100% difficult to escape

C:\test>test.bat complicatedString
var1="This & that ^" & the other thing ^ is 100% difficult to escape
var2="This & that ^" & the other thing ^ is 100% difficult to escape

C:\test>call test.bat complicatedString
var1="This & that ^" & the other thing ^ is 100% difficult to escape
var2="This & that ^" & the other thing ^ is 100% difficult to escape

C:\test>call call test.bat complicatedString
var1="This & that ^" & the other thing ^ is 100% difficult to escape
var2="This & that ^" & the other thing ^ is 100% difficult to escape
票数 10
EN

Stack Overflow用户

发布于 2012-09-30 14:39:34

经过一些测试和dbenham的回答,我们需要预测双插入符号,并将其替换为单个插入符号:

代码语言:javascript
复制
@SETLOCAL
CALL :TEST "blabla,blabla,^>blabla", "blaby"
@ENDLOCAL
@GOTO :EOF

:TEST
@SETLOCAL
@ECHO OFF
SET "list=%~1" & REM CHANGED
SET "list=%list:^^=^%" & REM ADDED
ECHO "LIST: %list%"
ECHO "ARG 1: %~1"
ECHO "ARG 2: %~2"
@ENDLOCAL   
@GOTO :EOF

然后,产出是:

代码语言:javascript
复制
"LIST: blabla,blabla,^>blabla"
"ARG 1: blabla,blabla,^^>blabla"
"ARG 2: blaby"

还请注意,奇怪的是:在SET "list=%list:^^=^%"中,%%之间的^^被视为两个字符,而不是转义的^。

票数 0
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/12655558

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档