基于其他节点+多级排序值的XSL查找节点
基于其他节点+多级排序值的XSL查找节点
提问于 2012-03-07 13:32:33
基本上，有两件事我需要弄清楚：
第三层的
- 多级排序
- ：如何选择另一个具有与当前
<term>的<narrowerterm>相等的<title>的<term>
我希望这是足够清楚的。我有一段时间没能找到我需要的东西了。
我的XML (摘录)：
<thesaurus>
<term>
<title>defense</title>
<narrowerterm>defense skills</narrowerterm>
<narrowerterm>defense actions</narrowerterm>
</term>
<term>
<title>defense skills</title>
<broaderterm>defense</broaderterm>
<narrowerterm>skill cd</narrowerterm>
<narrowerterm>skill xy</narrowerterm>
<narrowerterm>skill ab</narrowerterm>
</term>
<term>
<title>defense actions</title>
<broaderterm>defense</broaderterm>
<narrowerterm>actions against xy</narrowerterm>
<narrowerterm>actions against ab</narrowerterm>
</term>
</thesaurus>我的XSL：
<xsl:template match="thesaurus">
<html>
<body>
<xsl:for-each-group select="term" group-by="title">
<xsl:sort select="title"/>
<xsl:choose>
<xsl:when test="broaderterm">
</xsl:when>
<xsl:otherwise>
<xsl:choose>
<xsl:when test="use">
</xsl:when>
<xsl:otherwise>
<p>
<xsl:value-of select="current-grouping-key()"/><br/>
<xsl:for-each select="narrowerterm">
.<xsl:value-of select="."/><br/>
<xsl:for-each select="???"/>
..<xsl:value-of select="narrowerterm"/><br/>
</xsl:for-each>
</xsl:for-each>
</p>
</xsl:otherwise>
</xsl:choose>
</xsl:otherwise>
</xsl:choose>
</xsl:for-each-group>
</body>
</html>
</xsl:template>我想要的是：
defense
.defense actions
..actions against ab
..actions against xy
.defense skills
..skill ab
..skill cd
..skill xy我现在的处境是：
defense
.defense skills
.defense actions回答 1
Stack Overflow用户
回答已采纳
发布于 2012-03-07 14:24:27
我不认为这是一个分组任务，也不认为它需要XSLT2.0。
这个转换：
<xsl:stylesheet version="1.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output omit-xml-declaration="yes" indent="yes"/>
<xsl:strip-space elements="*"/>
<xsl:template match="/*">
<xsl:apply-templates select="term[not(broaderterm)]">
<xsl:with-param name="pIndent" select="''"/>
<xsl:sort select="title"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="term">
<xsl:param name="pIndent"/>
<xsl:value-of select="concat($pIndent, title, '
')"/>
<xsl:variable name="vSubterms" select=
"../term[broaderterm = current()/title]"/>
<xsl:variable name="vLeafSubterms" select=
"narrowerterm[not(. = /*/term[broaderterm = current()/title]/title)]"/>
<xsl:apply-templates select="$vSubterms | $vLeafSubterms">
<xsl:with-param name="pIndent" select="concat($pIndent, '.')"/>
<xsl:sort select="concat(self::term/title, self::narrowerterm/text())"/>
</xsl:apply-templates>
</xsl:template>
<xsl:template match="narrowerterm">
<xsl:param name="pIndent"/>
<xsl:value-of select="concat($pIndent, ., '
')"/>
</xsl:template>
</xsl:stylesheet>在提供的XML文档上应用时
<thesaurus>
<term>
<title>defense</title>
<narrowerterm>defense skills</narrowerterm>
<narrowerterm>defense actions</narrowerterm>
</term>
<term>
<title>defense skills</title>
<broaderterm>defense</broaderterm>
<narrowerterm>skill cd</narrowerterm>
<narrowerterm>skill xy</narrowerterm>
<narrowerterm>skill ab</narrowerterm>
</term>
<term>
<title>defense actions</title>
<broaderterm>defense</broaderterm>
<narrowerterm>actions against xy</narrowerterm>
<narrowerterm>actions against ab</narrowerterm>
</term>
</thesaurus>生成想要的、正确的结果
defense
.defense actions
..actions against ab
..actions against xy
.defense skills
..skill ab
..skill cd
..skill xy页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接：
https://stackoverflow.com/questions/9602460
复制相关文章
相似问题
腾讯云开发者
Copyright © 2013 - 2026 Tencent Cloud. All Rights Reserved. 腾讯云 版权所有
深圳市腾讯计算机系统有限公司 ICP备案/许可证号：粤B2-20090059 
粤公网安备44030502008569号
腾讯云计算（北京）有限责任公司 京ICP证150476号 | 京ICP备11018762号