Clojure约简方法中的NullPointerException

Question

在我的第一个Clojure程序中，我正在与NPE做斗争，并希望得到一些帮助。

call-elem是一个包含以下内容的结构：

• :id，字符串类似于some.packagename.SomeClass.someMethod
• :calls (子)，它是其他call-elem结构

的一个向量。

定义如下：

(defstruct call-struct :id :calls)

(defn- class-name [call]
  (let [id (call :id)]
    (.substring id 0 (.lastIndexOf id "."))))

(defn- method-name [call]
  (let [id (call :id)]
    (.substring id (inc (.lastIndexOf id ".")))))

我还有一个方法foo，它以一个class-map和一个call-elem作为参数。class-map是class-name到method-map的地图。method-map是method-name到variations列表的映射，每个variation都是带有:class-name、:method-name和:calls键的地图。:calls是其他变体的列表。foo函数应该返回一个包含两个元素的向量：-

第一个元素是一个类映射，它的新条目对应于call-elem及其子元素

• ，第二个元素是对应于参数

• 的变体映射。

以下是代码：

(declare foo' add-new-variation)

(defn foo [class-map call-elem]
  (let [children (call-elem :calls)
        class-name (class-name call-elem)
        method-name (method-name call-elem)]
    (if (empty? children)
      (let [new-variation {:class-name class-name
                           :method-name method-name
                           :calls []}
            new-class-map (add-new-variation class-map 
                                             class-name method-name 
                                             new-variation)]
        [new-class-map new-variation])
      (let [[new-class-map child-variations-list] 
            (reduce #(foo' %1 %2) (class-map '()) children)
            new-variation {:class-name class-name
                           :method-name method-name
                           :calls child-variations-list}
            new-class-map' (add-new-variation new-class-map 
                                              class-name method-name 
                                              new-variation)]
        [new-class-map' new-variation]))))

(defn foo' [[class-map variations-list] call-elem]
  (let [[new-class-map new-variation] (foo class-map call-elem)]
    [new-class-map (cons new-variation variations-list)]))

(defn add-new-variation [class-map class-name method-name variation]
  (let [method-map (if (contains? class-map class-name)
                     (class-map class-name) {})
        variations-list (if (contains? method-map method-name)
                          (method-map method-name) [])
        new-variations-list (conj variations-list variation)
        new-method-map (assoc method-map method-name new-variations-list)]
    (assoc class-map class-name new-method-map)))

当我尝试运行以下代码时：

(try
  (let [call-elem 
        (struct call-struct "Class1.method1" 
                [(struct call-struct "Class2.method1" [])])]
    (second (foo {} call-elem)))
  (catch Exception ex
         (.printStackTrace ex)))

我得到以下结果：

{:class-name "Class1",
 :method-name "method1",
 :calls ({:class-name "Class2", :method-name "method1", :calls []})}

但是，当我试图运行下面的代码时，将调用增加一个更深的级别，就会得到一个NullPointerException

(try
  (let [call-elem 
        (struct call-struct "Class1.method1" 
                [(struct call-struct "Class2.method1"
                         [(struct call-struct "Class3.method1" [])])])]
    (second (foo {} call-elem)))
  (catch Exception ex
         (.printStackTrace ex)))

下面是堆栈跟踪：

java.lang.NullPointerException
    at first.simple$foo.invoke(NO_SOURCE_FILE:46)
    at first.simple$foo_SINGLEQUOTE_.invoke(NO_SOURCE_FILE:55)
    at first.simple$foo$fn__1986.invoke(NO_SOURCE_FILE:46)
    at clojure.lang.ArrayChunk.reduce(ArrayChunk.java:58)
    at clojure.core.protocols$fn__5565.invoke(protocols.clj:30)
    at clojure.core.protocols$fn__5543$G__5538__5552.invoke(protocols.clj:11)
    at clojure.core$reduce.invoke(core.clj:5995)
    at first.simple$foo.invoke(NO_SOURCE_FILE:46)
    at first.simple$eval2010.invoke(NO_SOURCE_FILE:6)
    at clojure.lang.Compiler.eval(Compiler.java:6465)
    at clojure.lang.Compiler.eval(Compiler.java:6431)
    at clojure.core$eval.invoke(core.clj:2795)
    at clooj.repl$create_clojure_repl$repl_thread_fn__578$fn__589.invoke(repl.clj:147)
    at clojure.main$repl$read_eval_print__5967.invoke(main.clj:244)
    at clojure.main$repl$fn__5972.invoke(main.clj:265)
    at clojure.main$repl.doInvoke(main.clj:265)
    at clojure.lang.RestFn.invoke(RestFn.java:1523)
    at clooj.repl$create_clojure_repl$repl_thread_fn__578.invoke(repl.clj:145)
    at clojure.lang.AFn.run(AFn.java:24)
    at java.lang.Thread.run(Thread.java:680)

Answer 1

让我们仔细看看reduce in foo。我怀疑您试图将一个双元素集合作为reduce累加器的初始值传递，但是使用未引号的括号会使(class-map '())被视为要计算的表达式。更糟糕的是，它是有效的，因为class-map是一个clojure.lang.PersistentArrayMap，它实现了IFn。

因此，您没有创建两个元素列表，而是调用(class-map '())，它很可能返回nil，因为class-map中没有'()键。之后，在foo'中，您将尝试将nil绑定到[class-map variations-list]。轰隆隆。空指针异常

将reduce的第二个参数定义为向量应该可以解决这个问题。

--- before  2011-12-27 12:52:43.052218334 +0100
+++ after   2011-12-27 12:52:56.785477270 +0100
@@ -13,7 +13,7 @@
                                              new-variation)]
         [new-class-map new-variation])
       (let [[new-class-map child-variations-list]
-            (reduce #(foo' %1 %2) (class-map '()) children)
+            (reduce #(foo' %1 %2) [class-map '()] children)
             new-variation {:class-name class-name
                            :method-name method-name
                            :calls child-variations-list}