为什么CF FTP传输速度比标准FTP慢几倍？

Question

我有一个ColdFusion应用程序，用于在开发服务器和生产服务器之间传输文件。实际发送文件的代码如下所示：

ftp = new Ftp();
ftp.setUsername(username);
ftp.setPassword(password);
ftp.setServer(server);
ftp.setTimeout(1800);
ftp.setConnection('dev');
ftp.open();
ftp.putFile(transferMode="binary",localFile=localpath,remoteFile=remotepath);
ftp.close(connection='dev');

当使用上述代码发送文件时，我的上限小于100 on /s(通过接收服务器上的FileZilla监视)。如果我使用Windows命令行FTP工具发送完全相同的文件，我的速度将超过1000 of /s。

我只使用上面的代码创建了一个全新的文件，这对传输速度没有影响，所以我知道它与原始应用程序中的周围代码无关。

那么，是什么导致了这些极低的速度呢？

编辑:所有测试都在完成，将文件从我的生产服务器传输到我的开发服务器。我还尝试使用<cfftp>标记而不是cfscript，结果是相同的。

编辑#2：我最后使用了cfexecute，代码如下：

从我的FTP脚本：

public function sendFiles(required string localpath, required string remotepath) {
    this.writeFtpInstructions(localpath);
    exe = "C:\Windows\system32\ftp.exe";
    params = "-s:" & request.localapproot & "/" & "upload.txt";
    outputfile = request.localapproot & '/ftp.log';
    timeout = 120;
    Request.cliExec(exe,params,outputfile,timeout);
}

public function writeFtpInstructions(required string localpath) {
    instructions = request.localapproot & "/" & "upload.txt";
    crlf = chr(13) & chr(10);
    data = "";
    data &= "open " & this.server & crlf;
    data &= this.username & crlf;
    data &= this.password & crlf;
    data &= "cd " & request.remoteapproot & crlf;
    data &= "put " & localpath & crlf;
    data &= "quit";
    FileWrite(instructions, data);
}

cliExec()函数(创建包装器所必需的，因为在cfscript中没有等效的cfexecute )：

<cffunction name="cliExec">
    <cfargument name="name">
    <cfargument name="arguments">
    <cfargument name="outputfile">
    <cfargument name="timeout">
    <cfexecute
        name="#name#"
        arguments="#arguments#"
        outputFile="#outputfile#"
        timeout="#timeout#" />
</cffunction>

Answer 1

我一直在寻找，但我没有一个答案，为什么它是慢。但是，从理论上讲，您应该能够通过windows命令行使用cfexecute来完成这一任务。您甚至可以创建一个批处理文件并在一个调用中完成它。

Answer 2

根据我在CF9上使用cfftp的经验，不可能传输更大的文件。如果您查看FTP服务器端的活动传输，您会注意到传输是以最快的速度开始的，但是随着传输的数据越来越多，传输速度也会不断下降。在100 MB被转移后，减少开始变得非常大，直到它们最终达到一位数爬行。最后，传输超时&失败。我试图使用一个330 MB的文件&发现不可能使用cfftp进行传输。对于我来说，cfexecute不是使用标准windows ftp.exe的一个选项，因为它似乎不支持SFTP。

最后，我找到了一个外部java类，可以通过coldfusion使用&在JSch (http://www.jcraft.com/jsch/)上解决。具有讽刺意味的是，CF9似乎对CFFTP使用了这个类的变体(jsch-0.1.41m.jar)，但是使用这个最新下载的版本(jsch-0.1.45.jar)得到的结果却大不相同。

下面是我为概念的证明而编写的代码：

<cfscript>
    stAppPrefs = {
        stISOFtp = {
             server = 'sftp.server.com',
             port = '22',
             username = 'youser',
             password = 'pa$$w0rd'
        }
    };

    /* Side-Load JSch Java Class (http://www.jcraft.com/jsch/) */
    try {
        // Load Class Using Mark Mandel's JavaLoader (http://www.compoundtheory.com/?action=javaloader.index)
        /* 
        Add Mark's LoaderClass To The ColdFusion Class Path Under CF Admin:
        Java and JVM : ColdFusion Class Path : C:\inetpub\wwwroot\javaloader\lib\classloader-20100119110136.jar
        Then Restart The Coldfusion Application Service
        */
        loader = CreateObject("component", "javaloader.JavaLoader").init([expandPath("jsch-0.1.45.jar")]);
        // Initiate Instance
        jsch = loader.create("com.jcraft.jsch.JSch").init();
    }
    catch(any excpt) {          
        WriteOutput("Error loading ""jsch-0.1.45.jar"" java class: " & excpt.Message & "<br>");
        abort;
    }

    /* SFTP Session & Channel */
    try {
        // Create SFTP Session
        session = jsch.getSession(stAppPrefs.stISOFtp.username, stAppPrefs.stISOFtp.server, stAppPrefs.stISOFtp.port);
        // Turn Off & Use Username/Password
        session.setConfig("StrictHostKeyChecking", "no");
        session.setPassword(stAppPrefs.stISOFtp.password);
        session.connect();
        // Create Channel To Transfer File(s) On
        channel = session.openChannel("sftp");
        channel.connect();
    }
    catch(any excpt) { 
        WriteOutput("Error connecting to FTP server: " & excpt.Message & "<br>");
        abort;
    } 

    // Returns Array Of Java Objects, One For Each Zip Compressed File Listed In Root DIR
    // WriteDump(channel.ls('*.zip'));      
    // Get First Zip File Listed For Transfer From SFTP To CF Server
    serverFile = channel.ls('*.zip')[1].getFilename();

    /* Debug */
    startTime = Now();
    WriteOutput("Transfer Started: " & TimeFormat(startTime, 'hh:mm:ss') & "<br>");
    /* // Debug */

    /* Transfer File From SFTP Server To CF Server */
    try {
        // Create File On Server To Write Byte Stream To
        transferFile = CreateObject("java", "java.io.File").init(expandPath(serverFile));
        channel.get(serverFile, CreateObject("java", "java.io.FileOutputStream").init(transferFile));
        // Close The File Output Stream
        transferFile = '';
    }
    catch(any excpt) { 
        WriteOutput("Error transfering file """ & expandPath(serverFile) & """: " & excpt.Message & "<br>");
        abort;
    }

    /* Debug */
    finishTime = Now();
    WriteOutput("Transfer Finished: " & TimeFormat(finishTime, 'hh:mm:ss') & "<br>");
    expiredTime = (finishTime - startTime);
    WriteOutput("Duration: " & TimeFormat(expiredTime, 'HH:MM:SS') & "<br>");
    WriteOutput("File Size: " & NumberFormat(Evaluate(GetFileInfo(ExpandPath(serverFile)).size / 1024), '_,___._') & " KB<br>");
    WriteOutput("Transfer Rate: " & NumberFormat(Evaluate(Evaluate(GetFileInfo(ExpandPath(serverFile)).size / 1024) / Evaluate(((TimeFormat(expiredTime, 'H') * 60 * 60) + (TimeFormat(expiredTime, 'M') * 60) + TimeFormat(expiredTime, 'S')))), '_,___._') & " KB/Sec <br>");
    /* // Debug */

    channel.disconnect();
    session.disconnect();
    </cfscript>

结果：

Transfer Started: 09:37:57
Transfer Finished: 09:42:01
Duration: 00:04:04
File Size: 331,770.8 KB
Transfer Rate: 1,359.7 KB/Sec

所实现的传输速度与我使用FileZilla FTP客户端获得的速度相当&手动下载。我发现这种方法是解决cfftp不足的可行方法。