ActionBars中XP风格的字形烦恼

Question

我不想问太多关于组件外观的问题，但是现在应用程序中的外观似乎同样重要。

无论如何，请看下面的图片：

​

​

两者都在使用TActionManager和TActionMainMenuBar创建我的主菜单。图像左侧的菜单使用平台默认样式，右边的菜单使用由我的TActionManager定义的XP样式。

注意，当左菜单被高亮显示时，字形保持不变，这是完美的。

现在看看右边的XP样式菜单，字形画了一个阴影，稍微弹出，你可以看到透明度使字形看起来有点奇怪。

我想为我的UI启用XP样式，但是我不喜欢象形文字的绘制方式。我还想将我的TToolbar更改为TActionToolBar，并应用相同的XP样式，但这也会呈现相同的字形。

如何使XP样式菜单在TActionManager中定义，而不是像这样呈现图形呢？

谢谢。

编辑

这就是现在的结果，它应用了以下答案中的一些技巧：

​

​

克雷格。

Answer 1

下面是一些重写XP样式的示例代码，它创建了一个可以随意调整的派生类。这里的第一步是替换您自己派生的菜单项类，并更改其DrawGlyph代码，就像David告诉您的那样。我想你可能需要一些代码样本。

这只是一个简单的演示。它不会用象形文字在选中的项目周围绘制框，因此这种自定义样式与选中项不兼容，除非它们没有象形文字。您必须弄清楚如何绘制选中的字形项(在我编写DrawGlyphFrame的地方，如果设置了Action.Checked属性，则可以添加一些东西来绘制字形周围的选中状态矩形)。

unit MyActionControlStyle;

// Using this unit: Add it to your project. In your project set your
// style at runtime, add the unit to your uses clause and then set the style
// in that form's formcreate event:
//   ActionManager1.Style := MyActionControlStyle.MyStyle;

interface

uses Forms,
     Types,
     Controls,
     XPActnCtrls,
     XPStyleActnCtrls,
     ActnMan,
     ActnList,
     ActnMenus,
     ActnCtrls;

type

 TMyStyleMenuItem = class(TXPStyleMenuItem)
  protected
      procedure DrawGlyph(const Location: TPoint); override;

//      procedure DrawGlyphFrame(const Location:TPoint);

 end;
 TMyStyleMenuButton = class(TXPStyleMenuButton)
 end;

 TMyStyleActionBars = class(TXPStyleActionBars)
   // override the stuff that I want different than XP Style:
    function GetControlClass(ActionBar: TCustomActionBar;
      AnItem: TActionClientItem): TCustomActionControlClass; override;

 end;

var
 MyStyle:TMyStyleActionBars;

implementation


uses ToolWin, Classes, Windows, Graphics, GraphUtil, ImgList;
{ TMyStyleActionBars }

function TMyStyleActionBars.GetControlClass(ActionBar: TCustomActionBar;
  AnItem: TActionClientItem): TCustomActionControlClass;
begin
 if ActionBar is TCustomActionPopupMenu then
    Result := TMyStyleMenuItem
  else
  if ActionBar is TCustomActionMainMenuBar then
    Result := TMyStyleMenuButton
  else
    Result := inherited GetControlClass(ActionBar,AnItem);

end;

{ TMyStyleMenuItem }

procedure TMyStyleMenuItem.DrawGlyph(const Location: TPoint);
var
  ImageList: TCustomImageList;
  DrawEnabled: Boolean;
begin
//  DrawGlyphFrame(Location);
  if not HasGlyph and IsChecked then
  begin
    Canvas.Pen.Color := ActionBar.ColorMap.FontColor;
    DrawCheck(Canvas, Point((TextBounds.Left - 5) div 2, Height div 2), 2);
  end;

  if not HasGlyph then exit;
  if Assigned(Action) then
    ImageList := ActionClient.Action.ActionList.Images
  else
    ImageList := ActionClient.OwningCollection.ActionManager.Images;
  if not Assigned(ImageList) then exit;
  DrawEnabled := Enabled and (ActionClient.ImageIndex <> -1) or
    (csDesigning in ComponentState);
  ImageList.Draw(Canvas, Location.X, Location.Y, ActionClient.ImageIndex,
    dsTransparent, itImage, DrawEnabled);

end;

initialization
  MyStyle := TMyStyleActionBars.Create;
  RegisterActnBarStyle(MyStyle);
finalization
  UnregisterActnBarStyle(MyStyle);
  MyStyle.Free;
end.

Answer 2

这是通过VCL代码中的设计完成的。相关代码是TXPStyleMenuItem.DrawGlyph() in XPActnCtrls.pas。

更改行为的最简单方法是基于TXPStyleActionBars注册您自己版本的XP动作栏样式。有很多钩子可以让您重写TXPStyleMenuItem.DrawGlyph()。