TRichEdit颜色问题

Question

ans:= RichEdit1.Text     
for i:=1 to Length(ans) do
begin
   RichEdit1.SelStart :=  i-1;
   RichEdit1.SelLength:= 1;
   if ans[i] = correct[i] then
      RichEdit1.SelAttributes.Color := clRed
   else
      RichEdit1.SelAttributes.Color := clBlue;  

如果ans中的字母与correct字符串中的字母在相同的位置上匹配，则为红色，否则为蓝色。

我的问题是，当我再次键入整个RichEdit1文本时，其颜色与第一个字母相同(如果RichEdit1的第一个字母是蓝色的，那么整个文本就变成蓝色)。

顺便说一句，这不是我刚才简化的实际代码，因为有多个TRichEdits。

TRichEdits是只读的，我用类似于RichEdit1.Text := RichEdit1.Text+Key;的东西分配字母(这样做是因为它是一个多键盘程序，我需要分离用户输入)

，这是正确的行为吗？如何阻止颜色更改覆盖默认颜色？

更新:解决它..。以一种草率的方式(每当有人键入时应用默认颜色)，但我将保持这个打开，以防有人想出一个更好的解决方案。

Answer 1

正如您已经发现的，您必须在完成时重新设置默认颜色，例如：

ans := RichEdit1.Text;
for i := 1 to Length(ans) do 
begin 
  RichEdit1.SelStart := i-1; 
  RichEdit1.SelLength := 1; 
  if ans[i] = correct[i] then 
    RichEdit1.SelAttributes.Color := clRed 
  else 
    RichEdit1.SelAttributes.Color := clBlue;
end;
RichEdit1.SelStart := RichEdit1.GetTextLen;
RichEdit1.SelLength := 0;
RichEdit1.SelAttributes.Color := RichEdit1.Font.Color;

有更有效的方法来处理这个问题，而不是一次给一个字母着色，例如：

const
  colors: array[Boolean] of TColor = (clRed, clBlue);
var
  ans: string;
  start, len: Integer;
  cur_state: Boolean;

  procedure ColorRange(AStart, ALength: Integer; AColor: TColor);
  begin
    RichEdit1.SelStart := AStart;
    RichEdit1.SelLength := ALength;
    RichEdit1.SelAttributes.Color := AColor;
  end;

begin
  RichEdit1.Lines.BeginUpdate;
  try
    ans := RichEdit1.Text;
    start := 0;
    len := 0;
    cur_start := False;

    for i := 1 to Length(ans) do 
    begin 
      if (ans[i] = correct[i]) = cur_state then
        Inc(len)
      else begin
        if len > 0 then
          ColorRange(start, len, colors[cur_state]);
        start := i-1;
        len := 1;
        cur_state := not cur_state;
      end;
    end;
    if len > 0 then
      ColorRange(start, len, colors[cur_state]);
    ColorRange(RichEdit1.GetTextLen, 0, RichEdit1.Font.Color);
  finally
    RichEdit1.Lines.EndUpdate;
  end;
end;

此外，使用Text属性来追加单个Char是非常低效率的。使用SelText属性代替，例如：

RichEdit1.SelStart := RichEdit1.GetTextLen;
RichEdit1.SelLength := 0;
RichEdit1.SelAttributes.Color := ...; // optional
RichEdit1.SelText := Key;