SunGridEngine、秃鹰、扭矩作为PVM的资源管理器

Question

谁知道哪个资源管理器对PVM有好处？或者我不应该使用PVM，而是依赖MPI (或者它的任何版本，比如MPICH-2，还有其他更好的吗？)使用PVM的主要原因是因为在我之前开始这个项目的人开始使用PVM。然而，既然这个项目是我的(他还没有做任何依赖PVM的重要工作)，这可以很容易地改变，最好是一些易于安装的东西，因为安装和安装PVM是个大麻烦。

我倾向于SunGridEngine，看看我是如何拥有专用硬件的，在阅读了另一篇文章中哪些更适合专用硬件之后，SGE似乎是赢家。但是，我不确定它使用PVM的性能。想知道是否有人有过PVM和SGE的经验？

如果人们使用SGE，您用什么从计算机到计算机(或虚拟机到虚拟机)进行通信？

哦，如果这有关系的话，我将运行Perl应用程序/行。

有什么建议或想法吗？

谢谢大家的评论，

• Tyug

Answer 1

我使用Torque、SGE和LSF在Linux系统上运行PVM，没有任何问题。您是在问“是否可以使用SGE、Torque等来运行PVM应用程序？”

如果是这样，请查看下面的作业脚本示例。注意，除了每个脚本的标题之外，脚本几乎是相同的，这符合每个资源管理器的适当格式。

SGE作业脚本：

#!/bin/csh
#$ -N LTR-001
#$ -o LTR-001.output
#$ -e LTR-001.error
#$ -pe comp 24
#$ -l h_rt=04:00:00
#$ -A cmit2
#$ -cwd
#$ -V

# Setup envirnoment
setenv LD_LIBRARY_PATH /lfs0/projects/cmit2/opt-intel/overture-noX/lib:${LD_LIBRARY_PATH}
setenv PVM_ARCH LINUX
setenv PVM_ROOT /lfs0/projects/cmit2/opt-intel/pvm3
setenv PVM_BIN ${PVM_ROOT}/bin
setenv PVM_RSH /usr/bin/ssh
setenv MY_HOSTS pvm_hostfile

rm -f ~/.pvmprofile
env | grep PVM_ > ~/.pvmprofile

# Create file containing _unique_ host names.  Note that there are two possible sources of available hosts
sort -k 1,1 -u ${MACHINE_FILE} >! ${MY_HOSTS}

# Start PVM & add nodes
printf "%s\n%s\n" conf quit|${PVM_ROOT}/lib/pvm ${MY_HOSTS}
wait
sleep 2

#
# Run apps requiring PVM.
#

wait
# Exit PVM daemon
echo "reset" | $PVM_ROOT/lib/pvm
echo "halt" | $PVM_ROOT/lib/pvm

扭矩作业脚本：

#!/bin/csh
#PBS -N LTR-001
#PBS -o LTR-001.output
#PBS -e LTR-001.error
#PBS -l nodes=3:ppn=8
#PBS -l walltime=04:00:00
#PBS -q compute
#PBS -d .

# Setup envirnoment
setenv LD_LIBRARY_PATH /users/ps14/opt-intel/overture/lib:${LD_LIBRARY_PATH}
setenv PVM_ARCH LINUX64
setenv PVM_ROOT /users/ps14/opt-intel/pvm3
setenv PVM_BIN ${PVM_ROOT}/bin
setenv PVM_RSH ${PVM_ROOT}/ssh
setenv MY_HOSTS pvm_hostfile

rm -f ~/.pvmprofile
env | grep PVM_ > ~/.pvmprofile

# Create file containing _unique_ host names.  Note that there are two possible sources of available hosts
sort -k 1,1 -u ${PBS_NODEFILE} >! ${MY_HOSTS}

# Start PVM & add nodes
printf "%s\n%s\n" conf quit|${PVM_ROOT}/lib/pvm ${MY_HOSTS}
wait
sleep 2

#
# Run apps requiring PVM.
#

wait
# Exit PVM daemon
echo "reset" | $PVM_ROOT/lib/pvm
echo "halt" | $PVM_ROOT/lib/pvm