用CMake链接到TBB库

Question

我下载了tbb并放在我的存储库目录中：

> tree deps/tbb/ -d 
deps/tbb/
├── bin
├── cmake
│   └── templates
├── include
│   ├── serial
│   │   └── tbb
│   └── tbb
│       ├── compat
│       ├── internal
│       └── machine
└── lib
    ├── ia32
    │   └── gcc4.8
    └── intel64
        └── gcc4.8

在我的CMakeLists.txt中，我尝试过这样的方法：

include_directories("deps/tbb/include")


find_library(TBB_LIB
    NAMES
    tbbbind_debug
    tbbbind
    tbb_debug
    tbbmalloc_debug
    tbbmalloc_proxy_debug
    tbbmalloc_proxy
    tbbmalloc
    tbb_preview_debug
    tbb_preview
    tbb
    HINTS "${CMAKE_PREFIX_PATH}/deps/tbb/lib/intel64/gcc4.8"
)

add_executable(${PROJECT_NAME}
src/main.cpp
)

target_link_libraries(${PROJECT_NAME} PUBLIC ${TBB_LIB})

但是，使用cmake构建链接器会引发以下错误：

/usr/lib64/gcc/x86_64-suse-linux/7/../../../../x86_64-suse-linux/bin/ld：

无法找到-lTBB_LIB-NOTFOUND

collect2:错误: ld返回1退出状态

我不知道缺了什么。谢谢。

更新

此提交解决了前面的错误：

-    HINTS "${CMAKE_PREFIX_PATH}/deps/tbb/lib/intel64/gcc4.8"
+    HINTS "deps/tbb/lib/intel64/gcc4.8"

但是，会引发新的错误：

对`tbb::interface7::internal::task_arena_base::internal_current_slot()‘的

未定义引用

更新

除了find_library之外，还有哪些CMake工具可以链接到TBB共享库？

我尝试过一些CMake工具，但我不知道如何正确链接到TBB *.so文件！

Answer 1

受@AlexReinking答案的启发，下面是最后的实现：

    project(my-cpp-service VERSION 0.1.0)

    # Equivalent to command-line option of `-DCMAKE_PREFIX_PATH=...`
    list(APPEND CMAKE_MODULE_PATH "deps/tbb/cmake/")

    find_package(TBB REQUIRED)

    add_executable(${PROJECT_NAME}
        src/main.cpp
    )

    target_link_libraries(${PROJECT_NAME} PUBLIC
        TBB::tbb
    )

Answer 2

TBB有本机CMake支持。在我的系统上安装了Intel oneAPI，配置包在这里安装：

/opt/intel/oneapi/tbb/latest/lib/cmake/tbb/TBBConfig.cmake

因此，我只需要将/opt/intel/oneapi/tbb/latest添加到CMAKE_PREFIX_PATH中。在我的CMakeLists.txt中，我写道：

cmake_minimum_required(VERSION 3.21)
project(test-tbb)

find_package(TBB REQUIRED)

add_library(main main.cpp)
target_link_libraries(main PRIVATE TBB::tbb)
target_compile_features(main PRIVATE cxx_std_11)

TBB提供导入的目标TBB::tbb，这是您应该链接到的。

main.cpp只是这里的来源：https://stackoverflow.com/a/36782794/2137996

像这样建造：

$ cmake -G Ninja -S . -B build -DCMAKE_PREFIX_PATH=/opt/intel/oneapi/tbb/latest
$ cmake --build build --verbose
[1/2] /usr/bin/c++  -isystem /opt/intel/oneapi/tbb/2021.3.0/include  -MD -MT CMakeFiles/main.dir/main.cpp.o -MF CMakeFiles/main.dir/main.cpp.o.d -o CMakeFiles/main.dir/main.cpp.o -c /home/alex/test2/main.cpp
[2/2] : && /usr/bin/cmake -E rm -f libmain.a && /usr/bin/ar qc libmain.a  CMakeFiles/main.dir/main.cpp.o && /usr/bin/ranlib libmain.a && :

Answer 3

这篇文章帮助我解决了这个问题：

https://stackoverflow.com/a/41909627/3405291

错误通过以下方式得到解决：

include_directories("deps/tbb/include")

# https://stackoverflow.com/a/41909627/3405291
find_library(LIB_TBB                NAMES tbb               HINTS "deps/tbb/lib/intel64/gcc4.8")
find_library(LIB_TBBbind            NAMES tbbbind           HINTS "deps/tbb/lib/intel64/gcc4.8")
find_library(LIB_TBBmalloc_proxy    NAMES tbbmalloc_proxy   HINTS "deps/tbb/lib/intel64/gcc4.8")
find_library(LIB_TBBmalloc          NAMES tbbmalloc         HINTS "deps/tbb/lib/intel64/gcc4.8")
find_library(LIB_TBB_preview        NAMES tbb_preview       HINTS "deps/tbb/lib/intel64/gcc4.8")

add_executable(${PROJECT_NAME}
src/main.cpp
)

target_link_libraries(${PROJECT_NAME} PUBLIC
${LIB_TBB}
${LIB_TBBbind}
${LIB_TBBmalloc_proxy}
${LIB_TBBmalloc}
${LIB_TBB_preview}
)