使用XSLT从同一输入XML提取的最新日期更新输入XML。

Question

输入XML如下所示。我需要用从日期字段提取的最新日期输出xml，并用最大日期值更新日期字段。

<?xml version="1.0" encoding="UTF-8"?><rsp:response xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:rsp="rsp.com/employee/Response/v30"
xmlns:res="res.com/Member/details/v1">
<rsp:period>
    <res:Period>
        <rsp:date>2020-07-06T19:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-05-06T19:18:39</rsp:date>
    </res:Period>
</rsp:period></rsp:response>

下面的

是用于输入xml的

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:rsp="rsp.com/employee/Response/v30">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

<xsl:template
    match="*[local-name() = 'response']/*[local-name() = 'period']/*[local-name() = 'Period']/*[local-name() = 'date']">
    <xsl:copy>
        <xsl:apply-templates/>
        <xsl:copy-of select="*[local-name() = 'date']"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="/">
    <xsl:for-each
        select="*[local-name() = 'response']/*[local-name() = 'period']/*[local-name() = 'Period']/*[local-name() = 'date']">

        <xsl:sort select="translate(., '-T:Z', '')" data-type="number"/>
        <xsl:choose>
            <xsl:when test="position() = last()">
                <xsl:copy-of select="."/>
            </xsl:when>
        </xsl:choose>

    </xsl:for-each>
</xsl:template></xsl:stylesheet>

下面的

是该XSLT的输出。它能够提取最新日期，但无法在“传入日期”字段值中更新最新提取的日期。

<rsp:date xmlns:xs="http://www.w3.org/2001/XMLSchema"
      xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
      xmlns:rsp="rsp.com/employee/Response/v30"
      xmlns:res="res.com/Member/details/v1">2020-08-07T20:38:39</rsp:date>

下面的

是预期的输出

<?xml version="1.0" encoding="UTF-8"?><rsp:response xmlns:xs="http://www.w3.org/2001/XMLSchema"
xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance" xmlns:rsp="rsp.com/employee/Response/v30"
xmlns:res="res.com/Member/details/v1">
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period>
<rsp:period>
    <res:Period>
        <rsp:date>2020-08-07T20:38:39</rsp:date>
    </res:Period>
</rsp:period></rsp:response>

Answer 1

我建议你这样做：

XSLT1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:rsp="rsp.com/employee/Response/v30"
xmlns:res="res.com/Member/details/v1">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:variable name="max-date">
    <xsl:for-each select="/rsp:response/rsp:period/res:Period">
        <xsl:sort select="rsp:date"/>
        <xsl:choose>
            <xsl:when test="position() = last()">
                <xsl:value-of select="rsp:date"/>
            </xsl:when>
        </xsl:choose>
    </xsl:for-each>
</xsl:variable>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="rsp:date">
    <xsl:copy>
        <xsl:value-of select="$max-date"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

注意：

没有必要使用像your previous question);这样的黑客(正如您在上已经被告知的那样)。

1. ISO 8601日期将以文本的形式正确排序。