如何为连接到*.asl扩展程序的虚拟mdio-gpio设备配置ACPI *.asl

Question

我正在使用一个Q7模块(x86)，并尝试在Linux上配置我们的外围设备。但我不相信。我想我理解了ACPI的一些核心概念。

问题

CPU -> I2C -> PCA9575 GPIO Expander -> virtual,mdio-gpio -> Ethernet Phy

什么起作用

DefinitionBlock ("abc.asl", "SSDT", 2, "test", "HAL", 2)
{
    External (\_SB_.PCI0.D01D, DeviceObj)

    Scope (\_SB.PCI0.D01D)
    {
        Device (ABC0)
        {
            Name (_HID, "PRP0001")                      // must be PRP0001 that linux searches for compatible driver
            Name (_CRS, ResourceTemplate () {
                        I2cSerialBusV2 (
                                0x20,                  // SlaveAddress    : I2C Address
                                ControllerInitiated,   // SlaveMode       : ControllerInitiated
                                100000,                // ConnectionSpeed : max Bus Speed for this device
                                AddressingMode7Bit,    // AddressingMode  : Adress Mode
                                "\\_SB.PCI0.D01D",     // ResourceSource  : I2C host controller
                                0x00,                  // ResourceSourceIndex : must be 0
                                ResourceConsumer,      // ResourceUsage   : must be ResourceConsumer
                                ,                      // DescriptorName  : optional name for integer value which is an offset to a buffer field...
                                Exclusive              // Shared          : Shared or Exclusive
                                ,)                     // VendorData      : optional field                                
            })

            Name (_DSD, Package() {
                    ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
                    Package () {
                            Package (2) { "compatible", "nxp,pca9575"  },
                            Package ()  { "gpio-line-names", Package ()
                                                        {       "LED_Red",
                                                                "",
                                                                "MDC",
                                                                "MDIO",
                                                        }
                                        },
                        },
                    ToUUID("dbb8e3e6-5886-4ba6-8795-1319f52a966b"),
                    Package () {
                        Package () { "led-red",   "LED0" },
                        Package () { "mdc-gpios",  "MDC0" },
                        Package () { "mdio-gpios", "MDIO" },
                    }
            })

            Name (LED0, Package () {
            ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
            Package () {
                Package () {"gpio-hog", 1},
                Package () {"gpios", Package () {0, 1}},
                Package () {"output-low", 1},
              }
            })

... <placeholder for virtual,mdio-gpiocode here> ...

        }
    }
}

它识别了PCA9575的GPIO扩展器，并将其注册为Linux中的gpiochip。LED是固定的低和“霸道”。这部分似乎并没有完全错。

不起作用的

我将这段代码插入占位符

Device (MD00)
        {
            Name (_HID, "PRP0001")                      // must be PRP0001 that linux searches for compatible driver

            Name (_DSD, Package() {
                    ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
                    Package () {
                            Package (2) { "compatible", "virtual,mdio-gpio" },
                            Package () {"gpios", Package () {^MDC0, 2, 0, 
                                                             ^MDIO, 3, 0,}},
                            }
            })
        }

但是，当我试图通过configfs加载这个文件时，我可以在dmesg中看到一个错误消息，即_CRS字段中定义的资源的兼容字段缺失了。但我甚至没有定义_CRS字段。

我也不确定我的GPIO的定义是否正确。我无法使用Package () {"gpios", Package () {0, 1}},命令设置拉模式。

我问自己，是否应该再次定义为MDO设备中的GgioIo结构？

Name (_CRS, ResourceTemplate () {
        GpioIo (Exclusive, PullNone, 0, 0, IoRestrictionNone,
                "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {2}
        GpioIo (Exclusive, PullNone, 0, 0, IoRestrictionNone,
                "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {3}
    })

它似乎也不起作用，我很困惑。我不确定是否正确地使用了GPIO PCA9575驱动程序。我可以在哪里配置ACPI中的拉力偏差？驱动程序从of_加载配置，但我不知道如何在ACPI中定义它。我希望这里有人有个主意。

Answer 1

首先，让我们看看设计的主要架构：

+-------------------+
|  HOST             |       +------+
|              MDIO <------>+ MDIO |
|              Intf |       | Phy  |
|                   |       +--^---+
| +------+          |          |       +-----+
| | I²C  |          |          |       | LED |
| | host |          |          |       +--^--+
| +--^---+          |          |          |
|    |              |       +--+---+      |
+-------------------+       | I²C  |      |
     +----------------------> GPIO +------+
                            +------+

从这个原理图中，我们可以看到设备是如何相互关联的。现在让我们转到ACPI表示。在开始时，我们需要定义I S C GPIO扩展程序。通过元-acpi项目中的例子，我们可以找到如何描述PCA9535。假设我们找到了is主机控制器设备(根据您的文章中是\_SB_.PCI0.D01D)，并且您有没有锁定IRQ事件的扩展程序，那么下面是原始ASL节选和如何在驱动程序中匹配它与适当配置之间的混合：

Device (ABC0)
{

    Name (_HID, "PRP0001")
    Name (_DDN, "NXP PCA9575 GPIO expander")

    Name (RBUF, ResourceTemplate()
    {
        I2cSerialBusV2(0x0020, ControllerInitiated, 400000,
            AddressingMode7Bit, "\\_SB.PCI0.D01D",
            0x00, ResourceConsumer, , Exclusive, )
    })

    Name (_DSD, Package () {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () {"compatible", "nxp,pca9575"},
            Package () {"gpio-line-names", Package () {
                "LED_Red",
                "",
                "MDC",
                "MDIO",
            }},
        }
    })

    Method (_CRS, 0, NotSerialized)
    {
        Return (RBUF)
    }

    Method (_STA, 0, NotSerialized)
    {
        Return (0x0F)
    }
}

本文的摘录为提供了一种新的GPIO芯片，它的资源可以被其他消耗。

例如，在您的虚拟MDIO案例中(参见与GPIO相关的DSD设备属性 )

Device (MD00)
{
    Name (_HID, "PRP0001")

    Name (_CRS, ResourceTemplate () {
        GpioIo (Exclusive, PullDown, 0, 0, IoRestrictionOutputOnly,
            "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {2} // pin 2
        GpioIo (Exclusive, PullDown, 0, 0, IoRestrictionOutputOnly,
            "\\_SB.PCI0.D01D.ABC0", 0, ResourceConsumer) {3} // pin 3
    })

    Name (_DSD, Package() {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () { "compatible", "virtual,mdio-gpio" },
            Package () {
                "gpios", Package () {
                    ^MD00, 0, 0, 0, // index 0 in _CRS -> pin 2
                    ^MD00, 1, 0, 0, // index 1 in _CRS -> pin 3
                }
            },
        }
    })
}

现在是看LED绑定代码的时候了。为了澄清起见，占用是当您希望GPIO 提供程序消费资源本身的时。很可能不是你的案子。更好的方法是将其与LED GPIO驱动程序连接：

Device (LEDS)
{
    Name (_HID, "PRP0001")
    Name (_DDN, "GPIO LEDs device")

    Name (_CRS, ResourceTemplate () {
        GpioIo (
            Exclusive,                  // Not shared
            PullUp,                     // Default off
            0,                          // Debounce timeout
            0,                          // Drive strength
            IoRestrictionOutputOnly,    // Only used as output
            "\\_SB.PCI0.D01D.ABC0",     // GPIO controller
            0)                          // Must be 0
        {
            0,                          // LED_Red
        }
    })

    Name (_DSD, Package () {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () { "compatible", Package() { "gpio-leds" } },
        },
        ToUUID("dbb8e3e6-5886-4ba6-8795-1319f52a966b"),
        Package () {
            Package () { "led-0", "LED0" },
        }
    })

    /*
     * For more information about these bindings see:
     * Documentation/devicetree/bindings/leds/common.yaml,
     * Documentation/devicetree/bindings/leds/leds-gpio.yaml and
     * Documentation/firmware-guide/acpi/gpio-properties.rst.
     */
    Name (LED0, Package () {
        ToUUID("daffd814-6eba-4d8c-8a91-bc9bbf4aa301"),
        Package () {
            Package () { "label", "red" },
            Package () { "default-state", "on" },
            Package () { "gpios", Package () { ^LEDS, 0, 0, 1 } }, // active low
        }
    })
}

此外，您还可以在类似问题站点上查看StackOverflow (从给定的链接开始，并有对其余部分的引用)。