如何用Lauterbach CMM脚本逐行读写CSV文件

Question

我试图使用Lauterbach CMM脚本逐行读写CSV文件，但它不起作用。

我以为我可以将CSV文件的每一行作为普通文件读取，但如果在单元格数据中使用LF字符，则不正确:逐行读取csv文件将终止。我的意思是脚本将行读为部分。

你能让我知道逐行读取CSV文件吗？

我逐行读取CSV的代码：

OPEN #1 &csv_name /Read
WHILE !FILE.EOF(1)
(
    READ #1 %LINE &csv_row
    PRINT "&csv_row"
)

请提供有关如何使用Lauterbach CMM脚本逐行读写CSV文件的信息吗？

Answer 1

使用OPEN和READ的方式用于读取文本文件的一行。它们不是专门为CSV文件制作的。虽然CSV文件可能在一行中有一个行提要字符(当封装在双引号中时)，但普通文本文件的一行只是以一个行提要结尾。

因此，我认为这里有两个选项:逐字节将文件字节读取为二进制文件，或者将整个文件加载到调试器虚拟内存(VM)中，然后逐字节读取。

选项1：逐字节读取文件

OPEN #1 "&csv_name" /Read /Binary
WHILE !FILE.EOF(1)
(
    PRIVATE &line
    GOSUB getline "1"
    RETURNVALUES &line
    IF "&line"!=""
        ECHO "&line"
)
CLOSE #1
ENDDO

getline:
    PARAMETERS &fh
    PRIVATE &c &last &line &inquotes

    &last=0
    &inquotes=FALSE()

    READ #&fh &c
    WHILE !FILE.EOF(&fh)
    (
        IF (&last=='"')&&(&c!='"')
            &inquotes=!&inquotes
        IF (!&inquotes)&&(&c==CONvert.CHAR(0x0A))
        (
            IF &last==CONvert.CHAR(0x0D)
                &line=STRing.CUT("&line",-1)
            RETURN "&line"
        )
        &line="&line"+CONvert.CHAR(&c)
        &last=&c
        READ #&fh &c
    )
    RETURN "&line"

选项2：将整个文件加载到调试器虚拟内存(VM)中，并逐字节读取。

PRIVATEn &line &size &pos

&pos=0    
&size=OS.FILE.SIZE("&csv_name")
SILENT.Data.LOAD.Binary "&csv_name" VM:&pos
WHILE &pos<&size
(
    GOSUB getline "1" "&pos" "&size"
    RETURNVALUES &line &pos
    IF "&line"!=""
        ECHO "&line"
)
CLOSE #1
ENDDO

getline:
    PARAMETERS &fh &pos &size
    PRIVATE &c &last &line &inquotes

    &last=0
    &inquotes=FALSE()

    WHILE &pos<&size
    (
        &c=Data.Byte(VM:&pos)
        &pos=&pos+1
        IF (&last=='"')&&(&c!='"')
            &inquotes=!&inquotes
        IF (!&inquotes)&&(&c==CONvert.CHAR(0x0A))
        (
            IF &last==CONvert.CHAR(0x0D)
                &line=STRing.CUT("&line",-1)
            RETURN "&line" "&pos"
        )
        &line="&line"+CONvert.CHAR(&c)
        &last=&c
    )
    RETURN "&line" "&pos"