我们是否可以在EDN中重用已定义密钥的值？

Question

有什么方法可以重用EDN中定义的键值吗？

如果我有后续的EDN

{
   :abc "value1"
   :def :abc
}

当我在Clojure中阅读上面的EDN时，我希望传递'def‘键，value1的值为:abc。但是目前:abc字符串是在我使用EDN读字符串函数读取它时传递的。

Answer 1

在普通的EDN里没有这样的东西。但是，您可以构建一个两阶段传递，要么首先替换EDN字符串本身上的内容，要么在EDN通过操作一个数据结构进行分析之后进行更好的操作--例如：

(require '[clojure.edn :as edn])
(require '[clojure.walk :as walk])

(defrecord self [key])
(defn tag-self
  [v]
  (->self v))

(defn custom-readers []
  {'x/self tag-self})

(defn replace-self
  [coll]
  (walk/prewalk
   (fn [form]
     (if (map? form)
       (reduce-kv
        (fn [acc k v]
          (assoc acc k (if (= self (type v))
                         (get form (:key v))
                         v)))
        {}
        form)
       form))
   coll))

(replace-self
 (edn/read-string
  {:readers (custom-readers)}
  "[{:abc \"value1\"
     :def #x/self :abc}
    {:abc {:bbb \"value2\"
           :def #x/self :bbb}
     :def #x/self :abc
     :xyz {:aaa \"value3\"
           :nope #x/self :abc
           :def #x/self :aaa}}]"))

将返回：

[{:abc "value1", :def "value1"}
 {:abc {:bbb "value2", :def "value2"},
  :def {:bbb "value2", :def "value2"},
  :xyz {:aaa "value3", :nope nil, :def "value3"}}]

诀窍是，我使用我创建的#x/self标记读取器标记对当前映射的另一个键的引用，这将将值包装在self记录中。现在，我们只需遍历返回的数据结构，每次遇到self类型时，我们都会在同一个映射中用其:key属性的值替换它。

上面的replace-self遍历器是递归的，所以您可以看到它可以处理嵌套映射，甚至可以替换映射中的self引用，这些引用本身就是self引用的。不过，它只进行本地作用域，因此:nope #x/self :abc没有被父映射中的:abc值所取代，而且由于它自己的映射中没有:abc键，所以它的值被设置为nil。

自定义标记是可选的，我是这样做的，因为现在它适用于任何类型的键。但是您也可以使用keyword?代替-self，如果您希望这样做的话：

(defn replace-self
  [coll]
  (walk/prewalk
   (fn [form]
     (if (map? form)
       (reduce-kv
        (fn [acc k v]
          (assoc acc k (if (keyword? v)
                         (v form)
                         v)))
        {}
        form)
       form))
   coll))

(replace-self
 (edn/read-string
  "[{:abc \"value1\"
     :def :abc}
    {:abc {:bbb \"value2\"
           :def :bbb}
     :def :abc
     :xyz {:aaa \"value3\"
           :nope :abc
           :def :aaa}}]"))

这将与以前一样返回，只是不需要自定义标记和self记录：

[{:abc "value1", :def "value1"}
 {:abc {:bbb "value2", :def "value2"},
  :def {:bbb "value2", :def "value2"},
  :xyz {:aaa "value3", :nope nil, :def "value3"}}]