当图表上有很多数据时，如何使用增加更多的空间？

Question

我添加了yerrorbars关键字来显示图表上的标准偏差，但是由于我有大量的数据，所以图不太清楚，而且std偏差也不太清楚。在使用pi：set style line 4 lc rgb '#000000' lt 3 lw 1.5 ps 0.5 pt 3 pi 15在行样式上添加标准偏差时，我希望添加更多的空格。我该怎么做？

set label 1 "(a) workload: 50K r/s\npre-agg 77K tuples" at "300",6.5 font "{,10}"
plot t=0 "throughput-vs-latency-50K-8combiners-8reducers-all.csv" u (t==0?(t0=timecolumn(1,myTimeFmt),t=1):NaN, timecolumn(1,myTimeFmt)-t0):(column(2)/1000):(column(3)/1000) skip 2 notitle with linespoints ls 1 axis x1y1 \
, t=0 "throughput-vs-latency-50K-8combiners-8reducers-all.csv" u (t==0?(t0=timecolumn(1,myTimeFmt),t=1):NaN, timecolumn(1,myTimeFmt)-t0):(column(4)/1000) skip 2 notitle with linespoints ls 2 axis x1y1 \
, t=0 "throughput-vs-latency-50K-8combiners-8reducers-all.csv" u (t==0?(t0=timecolumn(1,myTimeFmt),t=1):NaN, timecolumn(1,myTimeFmt)-t0):(column(6)/1000) skip 2 notitle with linespoints ls 3 axis x1y2 \
, t=0 "throughput-vs-latency-50K-8combiners-8reducers-all.csv" u (t==0?(t0=timecolumn(1,myTimeFmt),t=1):NaN, timecolumn(1,myTimeFmt)-t0):(column(8)/1000):(column(9)/1000) skip 2 notitle with yerrorbars ls 4 axis x1y2 \

​

​

Answer 1

我想你得把数据的曲线分成两部分。第一部分将为数据集中的每个点绘制线和点；第二部分只为每N个点绘制错误条。需要的关键字是every N。

 set errorbars lt -1
 
 plot $DATA using 1:2 with linespoints lt 3 notitle, \
      $DATA every 5 using 1:2:3 with yerrorbars lt 3 title "DATA"

​

​

Answer 2

另一个建议:为什么不是一个“错误遮挡”，而不是拥挤的错误条？

代码：

### shaded area as error "bar"
reset session

# create some test data
set table $Data
    plot '+' u 1:(sin($1)):(rand(0)+0.25) w table
unset table

set key invert

plot $Data u 1:($2-$3):($2+$3) with filledcurves lc rgb "light-grey" ti "Error", \
     '' u 1:2 w lp ti "Data"
### end of code#

结果：

​

​

Answer 3

对于许多带有错误条的数据点，请考虑set bar 0、后台的错误条和/或透明性。此外，点的大小可以减少。

set samp 2000
set table $Data
    plot '+' u 1:(sin($1)+(rand(0)+0.25)):(rand(0)+0.25) w table
unset table

set bar 0

plot $Data with err lc rgb "grey" ti "Error", \
     '' u 1:2 w p lc "black" pt 6 ti "Data"

​

​