从NodeJs调用nim

Question

下面是文档：https://nim-lang.org/docs/backends.html#backends-the-javascript-target

我在fib.nim中有以下代码

proc fib(a: cint): cint {.exportc.} =
  if a <= 2:
    result = 1
  else:
    result = fib(a - 1) + fib(a - 2)

如果我运行nim js -o:fib.js fib.nim，那么它会将它编译成JS。

然后如何从nodejs运行fib？在这个例子中，它是一个html文件和一个浏览器，但是在节点上，我不知道如何导入fib函数。看起来.js文件缺少exports。我如何构建nim模块以便nodejs能够导入它？

Answer 1

我找不到编译nim模块到js模块的内置程序。解决方法是导入module对象并导出过程。

import jsffi

var module {.importc.}: JsObject

proc fib*(a: cint): cint =
  if a <= 2:
    result = 1
  else:
    result = fib(a - 1) + fib(a - 2)

module.exports.fib = fib

上面的内容可以用宏表示：

import macros, jsfii

var module {.importc.}: JsObject

macro exportjs(body: typed) =
  let bodyName = body.name.strVal
  result = newStmtList(
    body,
    newAssignment(
      newDotExpr(newDotExpr(ident"module", ident"exports"), ident(bodyName)),
      ident(bodyName)
    )
  )

proc fib*(a: cint): cint {.exportjs.} =
  if a <= 2:
    result = 1
  else:
    result = fib(a - 1) + fib(a - 2)

这个回购是在查找解决方案时出现的：https://github.com/nepeckman/jsExport.nim