错误：“子群op”：需要SPIR-V1.3

Question

我正在使用以下命令将GLSL文件编译到SPIR-V中：

C:/VulkanSDK/1.2.148.1/Bin/glslc C:/Users/jonat/Projects/sum.comp -o C:/Users/jonat/Projects/sum.spv

获取错误：

error: 'subgroup op' : requires SPIR-V 1.3

这个错误发生在第32行和第45行，它们都是sum = subgroupAdd(sum);

The 全GLSL码

#version 450
#extension GL_KHR_shader_subgroup_arithmetic : enable

layout(std430, binding = 0) buffer Input
{
   float inputs[];
};

layout(std430, binding = 1) buffer Output
{
   float outputs[];
};

layout (local_size_x_id = 1) in;
layout (constant_id = 2) const int sumSubGroupSize = 64;

layout(push_constant) uniform PushConsts
{
  int n;
} consts;

shared float sdata[sumSubGroupSize];

void main()
{
    float sum = 0.0;
    if (gl_GlobalInvocationID.x < consts.n)
    {
        sum = inputs[gl_GlobalInvocationID.x];
    }

    sum = subgroupAdd(sum);

    if (gl_SubgroupInvocationID == 0)
    {
        sdata[gl_SubgroupID] = sum;
    }

    memoryBarrierShared();
    barrier();

    if (gl_SubgroupID == 0)
    {
        sum = gl_SubgroupInvocationID < gl_NumSubgroups ? sdata[gl_SubgroupInvocationID] : 0;
        sum = subgroupAdd(sum);
    }

    if (gl_LocalInvocationID.x == 0)
    {
        outputs[gl_WorkGroupID.x] = sum;
    }
}

我有最新版本的VulkanSDK。

Answer 1

看来，要使glslc发出SPIR-V1.3，需要--target-env=vulkan1.1：

--target-env= ..。 生成的代码使用SPIR-V1.0，除了为Vulkan 1.1编译的代码使用SPIR-V1.3，而为Vulkan 1.5编译的代码使用SPIR-V1.5。 如果未指定此选项，则使用vulkan1.0 的默认值.。