在DataWeave 2.x中组装字符串(高效)

Question

我想用DataWeave (DW2.0，Mule Runtime4.3)编写一个函数，它可以用*的横幅来装饰文本消息，主要是为了帮助调用日志中的事件。

我想出来的是这个，但感觉还是有点像鲁伯·戈德伯格。那么，有没有一种更有效的方式来写这个，我忽略了吗？

%dw 2.0
output text/plain
var msg = "WT 3-4"

fun banner(in) =
    do {
        var width = sizeOf(in) + 4
        var standout = 1 to (width) map "*" joinBy ""
        ---
        standout ++ "\n* " ++ in ++ " *\n" ++ standout
    } 
---
//banner ("Hello World")
banner (msg)

这给了我：

***************
* Hello World *
***************

和

**********
* WT 3-4 *
**********

分别使用。

我对此有很多反对意见，但这个问题主要是关于横幅字符串的构造。

var standout = 1 to (sizeOf(in) + 4) map "*" joinBy ""

必须有一种更好的方法来算术组装字符串，而不是在宽度参数上使用map()和joinBy()。

对吗？

Answer 1

那太尴尬了。当这个想法被重构为字符串插值和使用正确的工具时，答案看起来要好得多。

%dw 2.0
output text/plain

import repeat from dw::core::Strings
var msg = "Read the Release Notes!"

fun banner(in) =
    do {
        var width = sizeOf(in) + 4
        var standout = repeat("*", width)
        ---
        "$(standout)\n* $(in) *\n$(standout)"       
    }
    
---
banner(msg)

然后，高度apt的输出变成：

***************************
* Read the Release Notes! *
***************************