如何使用cts:元素-属性-值()函数对元素的值进行排序？

Question

REQUIREMENT：尽快获取与查询匹配的员工id (/ Employee /@id)，并按连接日期(/Employee/JoiningDate)的升序排列

环境：MarkLogic DB有100万雇员XML

查询-1运行非常慢，但返回数据的顺序是正确的。

let $fullQuery :=
    cts:and-query((
        cts:directory-query("/employee/", "infinity"),
        cts:element-value-query(fn:QName("","DeptName"), "Sales", ("case-insensitive")),
        cts:element-value-query(fn:QName("","SubDeptName"), "Micro", ("case-insensitive"))
    ))
let $queryOptions := ("unfiltered", cts:index-order(cts:element-reference(fn:QName("","JoiningDate"),("type=dateTime")), "ascending"))
return cts:search(/Employee, $fullQuery, $queryOptions)!fn:string(./@id) (: Using ! to get id's in sorted order. This seems to affect performance quite heavily. :)

查询-2运行非常快，但返回的数据顺序不正确。

let $fullQuery :=
    cts:and-query((
        cts:directory-query("/employee/", "infinity"),
        cts:element-value-query(fn:QName("","DeptName"), "Sales", ("case-insensitive")),
        cts:element-value-query(fn:QName("","SubDeptName"), "Micro", ("case-insensitive"))
    ))
let $queryOptions := ("concurrent")
return cts:element-attribute-values(xs:QName("Employee"), xs:QName("id"), (), $queryOptions, $fullQuery)

如何使用上述两种方法之一实现需求？

Answer 1

cts:value-co-occurrences将允许您按一个索引进行排序，同时从另一个索引返回值。

例如：

for $v in cts:value-co-occurrences(
  cts:element-reference(xs:QName("JoiningDate"),
  cts:element-attribute-reference(xs:QName("Employee"), xs:QName("id")),
  (), 
  $fullQuery
)
return $v/cts:value[2]/string(.)