首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >如何在戈多走最长的路线或路径的两个角度之间进行LERP

问如何在戈多走最长的路线或路径的两个角度之间进行LERP
EN

Stack Overflow用户
提问于 2021-08-21 18:38:09
回答 1查看 1.1K关注 0票数 1

这是戈多中两个角度之间的LERP代码:

代码语言:javascript
复制
 func angle_dist(from, to):
    var max_angle = PI * 2
    var difference = fmod(to - from, max_angle)
    return (fmod(2 * difference, max_angle) - difference)

 func lerp_angle(from, to, weight):
    return from + angle_dist(from, to) * weight

我想要做的不是走最短的路,而是用最大的角度旋转另一条路。

​

​

正如上面的图片所示,头部是直接旋转到最近的角度,我希望头部向另一边旋转,也有一个角度限制,防止头部不现实地旋转360。

EN

回答 1

Stack Overflow用户

回答已采纳

发布于 2021-08-21 20:56:49

最短路

首先,lerp_angle是一个GDScript内建函数.它会走更短的路。

例如:

代码语言:javascript
复制
extends Sprite

var from := 0.0
var to := 0.0
var weight := 0.0

func _process(delta: float) -> void:
    if Input.is_action_pressed("Click"):
        var mouse_position = get_viewport().get_mouse_position()
        from = rotation
        to = Vector2.UP.angle_to(mouse_position - global_position)
        weight = 0.0

    weight = min(weight + delta * 10, 1.0)
    rotation = lerp_angle(from, to, weight)

如果你定义了你自己的,你需要叫它其他的东西,否则,戈多将不会使用它。例如:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var difference = fmod(to - from, TAU)
    var distance = fmod(2.0 * difference, TAU) - difference
    return from + distance * weight

这个实现是基于Godot的。让自己相信这相当于你的代码。记住,(PI * 2).是一个回合(助记符:它以t开头),这是您的max_angle max_angle

您也可能对fposmod和wrapf函数感兴趣。实际上,我们可以这样更短的实现:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var distance = wrapf(to - from, -PI, PI)
    return from + distance * weight

在这里,wrapf将给出-PI和PI之间的一个值。或者如果你喜欢:

代码语言:javascript
复制
func short_angle_dist(from, to):
    return wrapf(to - from, -PI, PI)

func my_lerp_angle(from, to, weight):
    return from + short_angle_dist(from, to) * weight

最长道

最长的方法是简单地采取最短的方式,并在相反的方向上增加一个旋转。也就是说,添加一个带有相反标志的TAU,即:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var distance = wrapf(to - from, -PI, PI)
    distance -= TAU * sign(distance)
    return from + distance * weight

或者如果你喜欢:

代码语言:javascript
复制
func complement_angle(angle):
    return angle - TAU * sign(angle)

func short_angle_dist(from, to):
    return wrapf(to - from, -PI, PI)

func long_angle_dist(from, to):
    return complement_angle(short_angle_dist(from, to))

func my_lerp_angle(from, to, weight):
    return from + long_angle_dist(from, to) * weight

自然方式

你觉得你想要一条最长的路。你不需要。你想要的是避免角色的脖子在动画中被勒死。

回到基本的lerp:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var distance = to - from
    return from + distance * weight

这将给你一个从来不超过一半回合的旋转。

嗯,除非你的角度没有归一化,但我们可以修正:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var distance = wrapf(to, -PI, PI) - wrapf(from, -PI, PI)
    return from + distance * weight

如果你想移动它从来不相交的角度,那是一个抵消角度的问题。结果是这样的:

代码语言:javascript
复制
func my_lerp_angle(from, to, zero, weight):
    to = wrapf(to - zero, -PI, PI)
    from = wrapf(from - zero, -PI, PI)
    var distance = to - from
    return from + distance * weight + zero

其中zero为中性位置(为避免偏转而偏离角度)。

或者像这样:

代码语言:javascript
复制
func my_lerp_angle(from, to, avoid, weight):
    to = wrapf(to - avoid + PI, -PI, PI)
    from = wrapf(from - avoid + PI, -PI, PI)
    var distance = to - from
    return from + distance * weight + avoid - PI

其中avoid是旋转不应交叉的角度。

此外,头部将有一个有限的范围。如果目标角(to)在它的外部,则完全不要停留。就像这样:

代码语言:javascript
复制
extends Sprite

var from := 0.0
var to := 0.0
var weight := 0.0
var zero := deg2rad(90)

func _process(delta: float) -> void:
    if Input.is_action_pressed("Click"):
        var mouse_position = get_viewport().get_mouse_position()
        from = rotation
        to = Vector2.UP.angle_to(mouse_position - global_position)
        weight = 0.0

    if abs(wrapf(to - zero, -PI, PI)) > deg2rad(170):
        return

    weight = min(weight + delta * 10, 1.0)
    rotation = my_lerp_angle(from, to, zero, weight)

func my_lerp_angle(from, to, zero, weight):
    to = wrapf(to - zero, -PI, PI)
    from = wrapf(from - zero, -PI, PI)
    var distance = to - from
    return from + distance * weight + zero

总是顺时针,总是逆时针

为了完整起见,这里有一个简单的顺时针方向的lerp:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var distance = fposmod(to - from, TAU)
    return from + distance * weight

逆时针方向:

代码语言:javascript
复制
func my_lerp_angle(from, to, weight):
    var distance = fposmod(to - from, -TAU)
    return from + distance * weight

增编:角度范围

以上我建议,当角度超出它的范围时,不要停下来。如果这不是你想要的,…我想你还想留着,但限制在一个范围内。

为了到达那里,我们需要从夹持角度开始。然而,我们需要确保它的规范化(例如wrapf(angle, -PI, PI)),然后夹紧:

代码语言:javascript
复制
func clamp_angle(angle, min_angle, max_angle):
    return clamp(wrapf(angle, -PI, PI), min_angle, max_angle)

或者只是从零开始的deviation角度:

代码语言:javascript
复制
func clamp_angle(angle, deviation):
    return clamp(wrapf(angle, -PI, PI), -deviation, deviation)

说到zero,我们需要考虑如何处理它。一种选择是夹紧输出,输出一旦与lerp代码合并,如下所示:

代码语言:javascript
复制
func my_lerp_angle(from, to, zero, deviation, weight):
    to = wrapf(to - zero, PI, -PI)
    from = wrapf(from - zero, PI, -PI)
    var distance = to - from
    var angle = wrapf(from + distance * weight, PI, -PI)
    return clamp(angle, -deviation, deviation) + zero

但是,请记住,这将截断lerp。因此,动画达到极限的速度将比停止时更快。

为了避免这种情况,不要夹紧输出,而是夹紧目标角度(to):

代码语言:javascript
复制
func my_lerp_angle(from, to, zero, deviation, weight):
    to = clamp(wrapf(to - zero, PI, -PI), -deviation, deviation)
    from = wrapf(from - zero, PI, -PI)
    var distance = to - from
    return from + distance * weight + zero
票数 2
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/68875814

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档