如何绘制局部态密度？

Question

我试着用这个脚本来画剧本，但效果不太好。

set term postscript enhanced colour
set output 'pdos.ps'
set key box font 'Helvetica, 12' top right noautotitle
set grid
set xlabel "E-E_f [eV]" font 'Helvetica, 20'
set ylabel "PDos(states/ev)" font 'Helvetica, 20'
set xzeroaxis
set xrange[-6:4]
set yrange[*:*]
plot 'Co_d.dat' u 1:2 w l lc "green", 'Mn_d.dat' u 1:2 w l lc "red', 'Sb_p.dat' u 1:2 w l lc "#4169E1"
set output

就像我提到的这张图片一样，我期待这样的情节。

​

​

我有这样的形象。

​

​

Answer 1

先绘制数据而不设置范围，默认为自动范围或set xrange[*:*]。然后你会看到感兴趣的区域。

在您的例子中，这不是您设置的set xrange[-6:4]，而是set xrange[6:16]。

​

​

​

​

可能，您正在寻找这样的脚本：

reset session

set key box font 'Helvetica, 12' top right noautotitle
set xlabel "E-E_f [eV]" font 'Helvetica, 20'
set xrange[-6:4]
set mxtics 2
set xzeroaxis lt 1 lc "black"
set ylabel "PDos(states/ev)" font 'Helvetica, 20'
set yrange[-10:10]
set yzeroaxis lt 1 dt 2 lw 1.5 lc "black"
set grid x,y

set label at first  0.25, first  5 "Spin-Up" font "Helvetica, 12"
set label at first  0.25, first -5 "Spin-Down" font "Helvetica, 12"
set label at first -0.5,  first  8 "Fermi-Level" font "Helvetica, 12" right
set arrow from first  0.75,  5.5 to 0.75, 7.5
set arrow from first  0.75, -5.5 to 0.75, -7.5
set arrow from first  -0.4, 8 to 0.0, 8

plot 'Co_d.dat' u ($1-12.6258):2     w l lc "green" ti "Co-4d", \
             '' u ($1-12.6258):(-$3) w l lc "green", \
     'Mn_d.dat' u ($1-12.6258):2     w l lc "red"   ti "Mn-4d", \
             '' u ($1-12.6258):(-$3) w l lc "red", \
     'Sb_p.dat' u ($1-12.6258):2     w l lc "#4169E1" ti "Sb-2p", \
             '' u ($1-12.6258):(-$3) w l lc "#4169E1"

​

​