"https://wfp-mysharepoint.com............“”Workbook.close无法运行

Question

背景资料：

这个工作簿是在共享点上的，我试图在桌面应用程序中运行一个Marco。

目标是在10分钟后自动关闭工作簿。我希望确保用户不打开工作簿而不使用它。

但是，当我运行以下代码时，会收到一条错误消息

“无法运行marco”https://wfp-mysharepoint.com............这个宏可能在此工作簿中不可用，或者marcos可能已禁用。

守则如下：

Private Sub Workbook_Open()
    Picktime
End Sub

Sub Picktime()
    savetime = Hour(Now) & ":" & Minute(Now) + 1 & ":" & Second(Now)
    Application.OnTime savetime, "Please_close"
End Sub

Sub Please_close()
    ThisWorkbook.Close (True)
End Sub

Answer 1

过程Workbook_Open是打开工作簿时自动运行的事件，因此必须在工作簿ThisWorkbook的范围内。与工作表相关的其他事件位于工作表的范围内。

所有其他代码都应该进入正常模块。特别是需要由Application.OnTime找到的代码只能定位在普通模块中。

所以在ThisWorkbook

Private Sub Workbook_Open()
    Picktime
End Sub

在普通模块中：

Public Sub Picktime()
    Dim SaveTime As Variant
    SaveTime = Now() + TimeValue("00:01:00")
    Application.OnTime EarliestTime:=SaveTime, Procedure:="Please_close"
End Sub

Public Sub Please_close()
    ThisWorkbook.Close SaveChanges:=True
End Sub

请注意，使用Now()为Now() + TimeValue("00:01:00")添加一分钟是容易的。