数据编织-如何才能得到订单Mule 4的总数？

Question

我有以下情况和问题，我使用CSV文件并与DW进行映射，按"PON“列分组，我需要得到此列的总顺序乘此列( Qty * Price )，我没有正确的结果，我将向您展示：

CSV数据：

PON,Item,Qty,Price
PON1000,2015,2,38.08
PON1000,2016,1,33.37
PON1001,2015,2,38.08

DW：

%dw 2.0
output application/json
---
payload groupBy ($.PON) pluck $ map ( () -> {
   "order": $[0].PON default "",
   "total": (sum( $.Price filter ($ != "") ) as Number) as String {format: "##,###.00"},
   "products": $ map {
       "product": $.Item,
       "price": ($.Price as Number) as String {format: "##,###.00"},
       "quantity": $.Qty
   }
})

取得的结果：

[
 {
   "order": "PON1000",
   "total": "71.45",
   "products": [
    {
     "product": "2015",
     "price": "38.08",
     "quantity": "2"
    },
    {
     "product": "2016",
     "price": "33.37",
     "quantity": "1"
    }
   ]
   },
   {
    "order": "PON1001",
    "total": "38.08",
    "products": [
    {
      "product": "2015",
       "price": "38.08",
       "quantity": "2"
     }
    ]
    }
   ]

我需要按顺序乘以“价格”*“数量”对应的值，最后将该值和该值之和，并按顺序将该值列在“总量”一栏中。

预期结果：

[
 {
   "order": "PON1000",
   "total": "109.53",
   "products": [
    {
     "product": "2015",
     "price": "38.08",
     "quantity": "2"
    },
    {
     "product": "2016",
     "price": "33.37",
     "quantity": "1"
    }
   ]
   },
   {
    "order": "PON1001",
    "total": "76.16",
    "products": [
    {
      "product": "2015",
       "price": "38.08",
       "quantity": "2"
     }
    ]
    }
   ]

任何帮助都将不胜感激。谢谢。

最诚挚的问候！

Answer 1

我只是补充了两件事：

1. 表示我使用了Arrays::sumBy，它让我们对每一项进行操作，并对所有结果进行求和。
2. I从代码中推断出价格是空的，所以我创建了safeNumber()来检查它，如果它是空的(默认情况下不工作)，返回0。

这是我到目前为止掌握的代码：

%dw 2.0
output application/json
import * from dw::core::Arrays
fun safeNumber(str) = if(isEmpty(str)) 0 else str as Number
---
payload groupBy ($.PON) pluck $ map ( () -> {
   "order": $[0].PON default "",
   "total": ($ sumBy( (i) -> safeNumber(i.Qty) * safeNumber(i.Price))) as String {format: "##,##0.00"},
   "products": $ map {
       "product": $.Item,
       "price": safeNumber($.Price) as String {format: "##,##0.00"},
       "quantity": $.Qty
   }
})

Answer 2

下面的脚本将帮助您。

%dw 2.0
output application/json
import divideBy from dw::core::Objects

---
payload groupBy $.PON  mapObject ((value, key, index) -> 
({
   order: (key),
   total: sum(value map ($.Qty  * $.Price)),
   value : value
})
) divideBy 3

Answer 3

您可以使用以下DataWeave表达式：

%dw 2.0
output application/json
---
payload groupBy $.PON pluck $ map (() -> {
    "order": $[0].PON,
   "total": sum($ map ($.Qty as Number * $.Price as Number)),
   "products": $ map { 
       "product": $.Item,
       "price": $.Price as Number,
       "quantity": $.Qty as Number
    }
})