PLSQL在ajax回调中的工作不正确。

Question

下面是甲骨文ajax回调过程：

DECLARE
    inspection_id number;
    inner_id number;
BEGIN
    inspection_id := apex_application.g_x01;
    inner_id := apex_application.g_x02;

    apex_debug.info('=====================================');
    apex_debug.info('DELETE ENTRY WITH INSPECTION_ID: '||inspection_id||' AND INNER_ID: '||inner_id);
    DELETE FROM CHLI_IMAGES WHERE (INSPECTION_ID = inspection_id AND INNER_ID = inner_id);
    apex_debug.info('ROWS DELETED '|| SQL%ROWCOUNT);

    apex_json.open_object;
    apex_json.write('success', true);
    apex_json.write('message', sqlerrm);
    apex_json.write('INSPECTION_ID', inspection_id);
    apex_json.write('INNER_ID', inner_id);
    apex_json.write('result', true);
    apex_json.close_object;
EXCEPTION
    WHEN OTHERS THEN
        apex_json.open_object;
        apex_json.write('success', false);
        apex_json.write('message', sqlerrm);
        apex_json.close_object;
END;

这里的js把它叫做：

apex.server.process("DeleteFromDB", {
                            x01: 0,   //inspection_id
                            x02: 2,   //inner_id
                        }, {
                            success: function (pData) {
                                console.log(pData);
                                if (pData.success === true) {
                                    resolve(true);
                                }
                            },
                            error: function (request, status, error) {
                                console.log(request);
                                resolve(false);
                            }
                        });    

真正令人毛骨悚然的是，它并不像预期的那样起作用。这段代码不仅删除了inespection =0& inner_id = 2的行，还删除了表中的其他行。两个ids正确地启动到我调试过程中的进程。JS片段在异步循环中，但我在调试中也检查了它只运行了一次。

令人毛骨悚然的是，它只适用于这条静态线：

DELETE FROM CHLI_IMAGES WHERE (INSPECTION_ID = 0 AND INNER_ID = 2);    

甲骨文先端有错误吗?还是我总是一次又一次地忽略一些事情。

提前谢谢你，

菲利普。

Answer 1

问题在于：

DELETE FROM CHLI_IMAGES WHERE (INSPECTION_ID = inspection_id AND INNER_ID = inner_id);

由于语言不区分大小写，这就意味着inspection_id和inner_id本身是相等的，即null。给变量不同的名称，例如：

declare
    l_inspection_id number;
    l_inner_id number;
begin
    l_inspection_id := apex_application.g_x01;
    l_inner_id := apex_application.g_x02;

    apex_debug.info('=====================================');
    apex_debug.info('DELETE ENTRY WITH INSPECTION_ID: '|| l_inspection_id ||' AND INNER_ID: '||l_inner_id);
    delete chli_images i where i.inspection_id = l_inspection_id and i.inner_id = l_inner_id;
    ...