标记满足条件的Ids，但Ids不是每行唯一的。

Question

我的数据集看起来是这样的(很抱歉画得太糟了)

​

我每一行都有非唯一的I，每次都有优惠券。

我要做的是数一数，有多少is有优惠券"a“和优惠券"b”。

例如，在图片中，仅对id 1进行计数。

谢谢您抽时间见我!

Answer 1

请测试此方法，如果它解决了您的问题，请告诉我：

CountUnique =
VAR TblSummary =
    ADDCOLUMNS (
        VALUES ( YourTable[ID] ),
        "UniqueCount", CALCULATE ( COUNTROWS ( YourTable ), YourTable[COUPON] IN { "a", "b" } )
    )
RETURN
    COUNTX ( FILTER ( TblSummary, [UniqueCount] > 1 ), [UniqueCount] )

如果我们在表上测试它，可视的：

​

​

Answer 2

与Ozan Sen类似的方法

建模->新表格

Count Table =
VAR _slt =
    ADDCOLUMNS (
        SUMMARIZE ( 'Table', 'Table'[ID] ),
        "Count",
            CALCULATE ( COUNT ( 'Table'[ID] ), 'Table'[Coupon] IN { "a", "b" } ) / 2
    )
RETURN
    FILTER ( _slt, [Count] >= 1 )

或作为一种措施

A or B Count =
IF (
    CALCULATE (
        COUNT ( 'Table'[ID] ),
        CONTAINSROW ( { "A", "B" }, 'Table'[Coupon] )
    ) > 1,
    1,
    0
)

Answer 3

另一个可定制的表：

Another Table =
VAR _search =
    DATATABLE ( "Search", STRING, { { "a" }, { "b" } } )
VAR _counted =
    COUNTROWS ( _search )
VAR _slt =
    ADDCOLUMNS (
        SUMMARIZE ( 'Table', 'Table'[ID] ),
        "Count",
            CALCULATE ( COUNT ( 'Table'[ID] ), 'Table'[Coupon] IN _search ) / _counted
    )
RETURN
    FILTER ( _slt, [Count] >= 1 )

或者更可定制的度量：

A or B Count =
VAR _search =
    DATATABLE ( "Search", STRING, { { "a" }, { "b" } } )
 VAR _counted =
    COUNTROWS ( _search )
RETURN
    IF (
        CALCULATE ( COUNT ( 'Table'[ID] ), CONTAINSROW ( _search, 'Table'[Coupon] ) ) >= _counted,
        1,
        0
    )