GetOpenFilename默认下载位置

Question

我在GetOpenFilename中没有看到任何参数来将默认文件夹设置为下载。

当前，它打开“文档”文件夹。是否可以将默认位置设置为“下载”文件夹。

如果没有用户名，我就无法将路径硬编码为下载。例如C：\Users\NameOfUser\下载

**********Solution**********

Dim FilePaths As FileDialogSelectedItems
Dim iFolderPath As String
iFolderPath = Environ("USERPROFILE") _
& Application.PathSeparator & "Downloads" & Application.PathSeparator

With Application.FileDialog(msoFileDialogFilePicker)
    .AllowMultiSelect = True
    .Filters.Clear
    .Filters.Add "Open CSV", "*.csv"
    .InitialFileName = iFolderPath

    If .Show <> -1 Then
        Do
        ans = MsgBox("No file selected. Cannot continue.", 53, "Try again")
        If ans = 2 Then Exit Do
            With Application.FileDialog(msoFileDialogFilePicker)
                .AllowMultiSelect = True
                .Filters.Clear
                .Filters.Add "Open CSV", "*.csv"
                .InitialFileName = iFolderPath
                .Show
            End With
        Loop
        If ans = 2 Then MsgBox "No file selected. User cancelled.", vbInformation, "Special"
        Exit Sub
    End If

    Set FilePaths = .SelectedItems
End With

Dim FilePath As Variant
For Each FilePath In FilePaths
Workbooks.Open FilePath
Next FilePath

Answer 1

选择要打开的文件(FileDialog)

这里有一种使用FileDialog object.

• Use Environ function来构建初始路径的不同方法。

Sub ChooseFilesToOpen()
    
    Dim iFolderPath As String: iFolderPath = Environ("USERPROFILE") _
        & Application.PathSeparator & "Downloads" & Application.PathSeparator
    
    Dim FilePaths As FileDialogSelectedItems
    
    With Application.FileDialog(msoFileDialogFilePicker)
        .AllowMultiSelect = True
        .Filters.Clear
        .Filters.Add "Excel Workbook", "*.xlsx"
        .InitialFileName = iFolderPath
    
        If .Show <> -1 Then
            MsgBox "Canceled.", vbExclamation
            Exit Sub
        End If
    
        Set FilePaths = .SelectedItems
    End With
    
    Dim FilePath As Variant
    
    For Each FilePath In FilePaths
        Debug.Print FilePath
    Next FilePath
    
End Sub