awk选择列1部分匹配列2的行

Question

我有一个像下面这样的"example_file“

a2022.1 a2022.1 80
a2022.1 a2022.2 90
a2022.1 a2023.1 80
a2022.2 a2022.2 90
a2022.2 a2023.1 40
a2022.3 a2022.1 50
b20225.1 a2022.1 80

我想选择第三列> 80的行，还有第一列(点前)和第二列(点之前)不同的行。

所以想要的结果是

a2022.1 a2023.1 80
b20225.1 a2022.1 80

因此，我已经设法排除了第3列<80以及第1和第2列相同的行，方法是使用以下行

awk '($3 > 80 && $1!=$2)' example_file

我试过awk '($3 > 80 && $1!~$2)' example_file，但它不排除行

a2022.1 a2022.2 90

我以为这很容易，但我想不出来。有人能帮忙吗？谢谢!

Answer 1

您可以使用此awk

awk -F '[.[:blank:]]' '$NF >= 80 && $1 != $3' file

a2022.1 a2023.1 80
b20225.1 a2022.1 80

在这里，-F '[.[:blank:]]'将输入字段分隔符设置为点或空格字符。这允许我们使用第一列的一部分作为$1和$2，第二列作为$3和$4。

交替使用gnu-awk

awk '$3 >= 80 && 
    gensub(/\..*/, "", "1", $1) != gensub(/\..*/, "", "1", $2)' file

a2022.1 a2023.1 80
b20225.1 a2022.1 80

Answer 2

第一种解决方案：和您的示例一起使用，请尝试遵循awk代码。本文利用split函数的awk函数，得到了字段的精确值，并对它们进行了比较。

awk '
{
  split($1,arr1,".")
  split($2,arr2,".")
}
$3>=80 && arr1[1]!=arr2[1]
'  Input_file

第二种解决方案：与GNU awk一起使用它的match功能，请尝试如下。使用regex ^.([^.]*)\..\s+.([^.]*)\..\s+(\S+) (通过捕获组)根据需求将值获取到数组中，并在进一步的条件下根据条件进行比较。

下面是下面代码中使用的正则表达式的在线演示。

awk '
match($0,/^.([^.]*)\..\s+.([^.]*)\..\s+(\S+)/,arr) && (arr[3]>=80 && (arr[1]!=arr[2]))
'  Input_file