QtLocation QML: MouseArea在悬停时停止更新

Question

我有一个qml地图应用程序，我添加了一个标记作为MapQuickItem。我有一个lat lon显示器连接到地图鼠标区，当我移动地图上的鼠标时，我会实时读取lat/lon，并且所有操作都很好。

marker.qml是一个带有鼠标区的mapquickItem，当鼠标“悬停”时，我将一个字符串写入地图的"labelLatLon“中。所有操作都很好，但是当我从标记中退出鼠标时，"labelLatLon“不再用鼠标坐标进行更新，它将停止更新lon。我移动鼠标，但不再更新.似乎主要的MouseArea停止“听”鼠标悬停。这是要测试的代码片段:交叉图像来自资源。

    Rectangle {
        id: mainWindow
        
        visible: true
        
        Plugin {
            id: mapPlugin
            name: "osm"
            PluginParameter {
                name: "osm.mapping.providersrepository.disabled"
                value: "true"
            }
            PluginParameter {
                name: "osm.mapping.providersrepository.address"
                value: "http://maps-redirect.qt.io/osm/5.6/"
            }
        }       
        
        function addMarker(latitude,longitude) {
            
            var Component = Qt.createComponent("qrc:///qml/marker.qml")
            var item = Component.createObject(Item, {
                                                  coordinate: QtPositioning.coordinate(latitude, longitude)
                                              })
            map.addMapItem(item);         
        }
                
        function setLatLonBox(coordinate) {    
            labelLatLon.text= "Lat: %1; Lon:%2".arg(coordinate.latitude).arg(coordinate.longitude)  
        }
        
        Map {
            id: map
            
            gesture.enabled: true
            copyrightsVisible : true
            anchors.fill: parent
            plugin: mapPlugin
            center: QtPositioning.coordinate(44.0, 9.3) // La Spezia
            zoomLevel: 10
            Component.onCompleted:addMarker(44.0, 9.3)
            
            
            MouseArea  {
                id: mapMouseArea
                property int pressX : -1
                property int pressY : -1
                property int jitterThreshold : 10
                property int lastX: -1
                property int lastY: -1
                property var coordinate: map.toCoordinate(Qt.point(mouseX, mouseY))
                
                anchors.fill: parent
                acceptedButtons: Qt.LeftButton | Qt.RightButton
                hoverEnabled : true

                ColumnLayout {
                    id: layout
                    spacing: 5
                    z: 5  // ordine alto
                                        
                    Rectangle {
                        id: latLonArea
                        z: 5  // ordine alto
                        width: 320
                        height: 40
                        color: "grey"
                        opacity: 0.7
                        border.color: "black"
                        border.width: 1

                        Label {
                            id: labelLatLon
                            anchors.verticalCenter:  parent.verticalCenter
                            anchors.horizontalCenter:  parent.horizontalCenter
                            font.bold: true
                            color: "black"
                            text: "Lat: %1; Lon:%2".arg(mapMouseArea.coordinate.latitude).arg(mapMouseArea.coordinate.longitude)                            
                        }
                    }                    
                }
            }
        }
    }

和marker.qml

    MapQuickItem {
        id: marker
        z: 2  //ordine basso
        anchorPoint.x: marker.width / 2
        anchorPoint.y: marker.height /2
        
        property int idx
        
        sourceItem: Image{
            id: icon
            source: "../symbols/Red_Cross.png"
            sourceSize.width: 40
            sourceSize.height: 40
            opacity: markerMouseArea.pressed ? 0.6 : 1.0
        }
            
        MouseArea {
            id: markerMouseArea
            property int pressX : -1
            property int pressY : -1
            property int jitterThreshold : 10
            property int lastX: -1
            property int lastY: -1
            anchors.fill: parent
            acceptedButtons: Qt.LeftButton | Qt.RightButton
            hoverEnabled : true
            drag.target: marker
            
            onEntered: {
                var coordinate = map.toCoordinate(Qt.point(mouseX, mouseY));
                setLatLonBox(coordinate);
            }
        }
    }

Answer 1

您的问题是标签文本属性。

text: "Lat: %1; Lon:%2".arg(mapMouseArea.coordinate.latitude).arg(mapMouseArea.coordinate.longitude)

一旦您用setLatLonBox覆盖它，它上的所有绑定都会消失。您必须在退出MQI鼠标区域(或重新输入地图鼠标区域)后重新设置它。