如何使用SPARQL构造SHACL形状

Question

我有一个包含以下信息的ttl文件：

ex:Shape1
    a sh:NodeShape ;
    sh:property ex:Property-1
    rdfs:label "Shape 1"

ex:Property-1
    a sh:PropertyShape ;
    sh:path ex:property1
    sh:name "Property 1"

ex:property1
    a owl:DatatypeProperty

在将上述数据加载到我的三重存储区(其中已经包含了许多形状)之后，我可以使用什么查询来检索相同的数据呢？

我尝试了一些东西，最接近的是下面的查询，它返回我的三重存储中的每个形状(但不是ex:property1)：

PREFIX sh: <http://www.w3.org/ns/shacl#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
PREFIX owl: <http://www.w3.org/2002/07/owl#>
PREFIX ex: <http://example.com/#>

CONSTRUCT {
  ?subject ?predicate ?object
}
WHERE {
  ex:Shape1 sh:property ?propertyShape .
  { ex:Shape1 ?predicate ?object } UNION {  ?propertyShape ?predicate ?object }
  ?subject ?predicate ?object .
}

Answer 1

这个查询似乎满足了我的需要：

PREFIX sh: <http://www.w3.org/ns/shacl#>
PREFIX ex: <http://example.com/#>

CONSTRUCT {
  ?subject ?predicate ?object
}
WHERE {
  {
    bind(ex:Shape1 as ?subject)
    ex:Shape1 ?predicate ?object
  }
  UNION
  {
    ex:Shape1 sh:property ?subject .
    ?subject ?predicate ?object
  }
  UNION
  {
    ex:Shape1 sh:property/sh:path ?subject .
    ?subject ?predicate ?object
  }
}