地形中多个子网的subnet_id值

Question

varaible.tf


variable "subnets" {
  type = map(any)
  default = {
    subnet1 = {
      "key"              = "subnet_1"
      "address_prefixes" = ["10.20.30.0/24"]
    }

    subnet2 = {
      "key"              = "subnet_2"
      "address_prefixes" = ["10.20.40.0/24"]
    }

  }
}



main.tf


resource "azurerm_subnet" "subnet1" {
  for_each             = var.subnets
  name                 = each.value["key"]
  resource_group_name  = azurerm_resource_group.azureDevops.name
  virtual_network_name = azurerm_virtual_network.vnet1.name
  address_prefixes     = each.value["address_prefixes"]
}

想要将安全组附加到我的所有子网。不止一种价值。它对subnet_id的抛出错误。

resource "azurerm_subnet_network_security_group_association" "example" {

subnet_id = [for subnet in azurerm_subnet.subnet1 : subnet.id]
network_security_group_id = azurerm_network_security_group.tamopsnsg.id
}

它对subnet_id值的抛出错误。如何附加到多个子网？

Answer 1

您在这里试图实现的是chaining for_each between resources的典型用例，其中由一个for_each资源创建的映射值成为下游资源的for_each值。

例如：

variable "subnets" {
  # NOTE: Better to specify an exact type constraint
  # so that Terraform can give you better feedback
  # when you make a mistake elsewhere in the
  # configuration.
  type = map(object({
    key              = string
    address_prefixes = set(string)
  }))
}

resource "azurerm_subnet" "example" {
  for_each = var.subnets

  name                 = each.value.key
  resource_group_name  = azurerm_resource_group.azure_devops.name
  virtual_network_name = azurerm_virtual_network.vnet1.name
  address_prefixes     = each.value.address_prefixes
}

resource "azurerm_subnet_network_security_group_association" "example" {
  for_each = azurerm_subnet.example

  subnet_id                 = each.value.id
  network_security_group_id = azurerm_network_security_group.tamopsnsg.id
}

这依赖于azurerm_subnet.subnet1是一个事实，因为该资源使用for_each，它是从实例键到表示每个子网的对象的映射。由于var.subnets的工作方式，实例键将与for_each的键完全匹配，因此对于您声明的每个子网，您还将声明一个相应的安全组关联：

• azurerm_subnet.example["subnet1"]对应于azurerm_subnet_network_security_group_association.example["subnet1"]
• azurerm_subnet.example["subnet2"]对应于azurerm_subnet_network_security_group_association.example["subnet2"]

关联资源块中的each.value将是表示您声明的子网的对象，而不是var.subnets的一个元素，因此您可以访问each.value.id以获取相应子网的远程对象ID。