为什么Stata返回“未知函数+inrange()”？

Question

我正在学习Stata编程与这本书，介绍Stata编程，第二版。

在第4章中，有一个用于测试其他变量是否满足逻辑条件的generate代码，代码如下：

foreach v of varlist child1-child12{
        local n_school "`n_school' + inrange(`v', 1, 5)"
    }
    gen n_school = `n_school'

当我修改这个代码以适应我自己的数据时，

foreach v of varlist qp605_s_1-qp605_s_5 {
        local n_med  "`n_med' + inrange(`v', 1, 5)"
    }
    gen n_med = `n_med'

如果qp605_s_1的值从1到17不等，那么Stata返回：

. foreach v of varlist qp605_s_1-qp605_s_5 {
  2.         local n_med "`n_med' + inrange(`v', 1, 5)"
  3. }

. gen n_med = `n_med'
unknown function +inrange()
r(133);

有什么想法吗?这段代码有什么问题？

Answer 1

这是另一种方法。

* Example generated by -dataex-. For more info, type help dataex
clear
input float(var1 var2)
1 5
2 6
3 7
4 8
end

gen wanted = .

mata :

data = st_data(., "var*")

st_store(., "wanted", rowsum(data :>= 1 :& data :<= 5))

end

list

     +----------------------+
     | var1   var2   wanted |
     |----------------------|
  1. |    1      5        2 |
  2. |    2      6        1 |
  3. |    3      7        1 |
  4. |    4      8        1 |
     +----------------------+

Answer 2

我知道我错在哪里了

本地n_med以+开头，因此我将其更改为：

local n_med 0
foreach v of varlist qp605_s_1-qp605_s_5{
    local n_med "`n_med' + inrange(`v', 1, 5)"
}
gen n_med = `n_med',after(qp605_s_5)

而且起作用了！

顺便说一句，根据Stata编程的介绍，这个方法比首先generate一个变量全部为零，然后通过一个循环进行replace要快，因为replace命令比generate慢，所以最好避免使用replace。