Gnu图:在绘制矩形时使用图0和图1。

Question

对于使用“图0”和“图1”的一些启示，我会很高兴的：

目标是将矩形绘制成一个图形，但是当我试图使用图0和图1来表示左右边界时，当绘制整个背景时，水平条纹不会。

我在http://gnuplot.sourceforge.net/demo/rectangle.html学习第二个例子

reset session
set xrange [0:6]
set yrange [0:25]

set obj 1 rect from graph 0,graph 0 to graph 1,graph 1 fc "red"   # paint the background

set obj 2 rect from graph 0,5 to graph 1,12 fc "green"            # produces nothing

set obj 3 rect from 'graph 0', 3 to 'graph 1',10 fc "blue"        # produces nothing 

set obj 4 rect from 'graph 0', 4 to 6,8 fc "yellow"               # this works. '...' and 6 required 

plot 'data02.txt'

我遗漏了什么？

我在Ubuntu20.04.4LTS上的gnu图是5.2.8

谢谢你的帮忙!

Answer 1

你为什么写'graph 0'而不是graph 0？并检查help coordinates

如果没有指定x的坐标系，则首先使用

。如果没有指定y的系统，则采用用于x的系统。

因此，例如，graph 0, 5和graph 0, 12将在图形之外。如果你指的是x和y坐标，你应该写graph 0, first 5和graph 0, first 12，或者写0,5和0,12 .实际上，在您的例子中，graph 0与first 0是相同的。这取决于你想要什么。

检查以下脚本。

脚本：

### coordinate sytems graph and first
reset session

set xrange [0:6]
set yrange [0:25]

set obj 1 rect from graph 0,       0 to graph 1,        1 fc "red"
set obj 2 rect from graph 0, first 5 to graph 1, first 12 fc "green"
set obj 3 rect from graph 0, first 3 to graph 1, first 10 fc "blue"
set obj 4 rect from graph 0, first 4 to       6,        8 fc "yellow"

plot NaN notitle   # or plot some data
### end of script

结果：

​

​