为什么我的NFT元数据不显示在opensea上？

Question

我正在用开放的齐柏林飞艇开发一份关于ETH的NFT合同，并且达到了在rinkeby上部署的阶段。然而，tokenURI和contractURI出现了一个问题，因为图像和元数据没有在开放海域显示。

我像这样实现了tokenURI和ContractURI：

// SPDX-License-Identifier: MIT
pragma solidity ^0.8.1;

import "hardhat/console.sol";
import "@openzeppelin/contracts/token/ERC721/ERC721.sol";
//access control
import "@openzeppelin/contracts/access/Ownable.sol";

// Helper functions OpenZeppelin provides.
import "@openzeppelin/contracts/utils/Counters.sol";
import "@openzeppelin/contracts/utils/Strings.sol";

import "./libraries/Base64.sol";

contract MetropolisWorldGenesis is ERC721, Ownable {

....

string private _contractURI;

function contractURI() public view returns (string memory) {
        return _contractURI;
    }

function tokenURI(uint256 _tokenId) public view override returns (string memory) {
        PropertyAttributes memory propAttributes = nftHolderAttributes[_tokenId];

        string memory json = Base64.encode(
            abi.encodePacked(
                '{"name": "',
                propAttributes.name,
                '", "description": "',propAttributes.description,'", "image": "',
                propAttributes.image,
                '", "attributes": [ { "trait_type": "Tower", "value": ',propAttributes.properties.tower,', "trait_type": "District", "value":',propAttributes.properties.district, ', "trait_type": "neighborhood", "value":',propAttributes.properties.neighborhood,',]}'
            )
        );

        string memory output = string(
            abi.encodePacked("data:application/json;base64,", json)
        );
        
        return output;
    }


    function setContractURI(
        string memory name, string memory desc,
        string memory image,string memory link, 
        uint royalty) public onlyOwner() {

        string memory x = Base64.encode(
            abi.encodePacked(
                '{"name": "',
                name,
                '", "description": "',
                desc,
                '", "image": "', 
                image,
                '", "external_link": "', 
                link,
                '","seller_fee_basis_points":"', royalty, // 100 Indicates a 1% seller fee
                '", "fee_recipient": "0xA97F337c39cccE66adfeCB2BF99C1DdC54C2D721" }' // Where seller fees will be paid to.}
            )
        );
        _contractURI = string(abi.encodePacked(
                "data:application/json;base64,", x
            ));
        console.log("contract uri updated");
    }
}

当在本地运行时，返回tokenURI将给出以下输出，该输出将解析为更正浏览器中的数据：

data:application/json;base64,eyJuYW1lIjogIkdpbGRlZCBBdHRpYyIsICJkZXNjcmlwdGlvbiI6ICJUaGUgQXN0cm9ub21lcidzIFN0dWRpbwpVbmRlciB0aGUgZG9tZSBpcyBhIHBsYW5ldHJpdW0gClJlc2VhcmNoZXMgdGhlIG9yaWdpbnMgb2YgdGhlIE1ldHJvcG9saXMiLCAiaW1hZ2UiOiAiaXBmczovL1FtWnc3NzY1ZG04aHBIRndITDl3b29RSkNzSkd6TFR3WTIyNjVDR1lpeFB3aUciLCAiYXR0cmlidXRlcyI6IFsgeyAidHJhaXRfdHlwZSI6ICJUb3dlciIsICJ2YWx1ZSI6IFRvd2VyIDEsICJ0cmFpdF90eXBlIjogIkRpc3RyaWN0IiwgInZhbHVlIjpIaWdoLUZseWVyLCAidHJhaXRfdHlwZSI6ICJuZWlnaGJvcmhvb2QiLCAidmFsdWUiOkZyZWUgQWxsZXkgUXVhcnRlcnMsXX0=

你知道我哪里出错了吗？

Answer 1

JSON属性数组的格式不正确，值没有双引号，数组中的每个项都应该是带有trait-type和value键的对象。

当前：

[ { "trait_type": "Tower", "value": Tower 1, "trait_type": "District", "value":High-Flyer, "trait_type": "neighborhood", "value":Free Alley Quarters,]

应：

[
  {"trait_type":"Tower","value":"Tower 1"},
  {"trait_type":"District","value":"High-Flyer"},
  {"trait_type":"neighborhood","value":"Free Alley Quarters"}
]

这个片段应该会生成正确的输出，尽管我还没有对它进行测试。

string memory json = Base64.encode(
    abi.encodePacked(
        '{"name":"', propAttributes.name,
        '","description":"',propAttributes.description,
        '","image":"', propAttributes.image,
        '","attributes":[{"trait_type":"Tower","value":"', propAttributes.properties.tower, '"},{"trait_type":"District","value":"', propAttributes.properties.district, '"},{"trait_type": "neighborhood","value":"', propAttributes.properties.neighborhood, '"}]}'
    )
);