如何修复ngspice的交流分析错误？

Question

我正试图对我做的电路进行交流分析。我得到了一个与我所使用的模型有关的错误，我不知道如何修复它。这是每当我运行代码时都会收到的错误。

doAnalyses: AC:  Timestep too small; frequency = 0: trouble with x1:dx-instance d.x1.dc


ac simulation(s) aborted
Error: no such vector vout
  in term: mag(v(vout))

Error: no such vector vout
  in term: phase(v(vout))

我的香料代码

.include "C:\Users\rest_of_file_path\Spice64\bin\NE5534.lib"

R7 Vout GND 10k
R6 0 GND 0
R4 Vin_p GND 100k
X1 Vin_p Vin_n Vout Vdd Vss NE5534
V1 Vdd GND dc(36)
V2 Vss GND dc(-36)
R2 Vin Vin_p 1k
R3 GND Vin_n 1k
R1 Vin GND 1k
R5 Vin_n Vout 100k
I1 Vin GND dc 0 ac 1 sin(0 10u 1k)

.control
ac dec 100 20 20k
plot mag(v(Vout))
plot phase(v(Vout))
.endc

.end

这是我正在使用的模型。它是从原制造商下载的。

* NE5534 OPERATIONAL AMPLIFIER "MACROMODEL" SUBCIRCUIT
* CREATED USING PARTS RELEASE 4.01 ON 04/10/89 AT 12:41
* (REV N/A)      SUPPLY VOLTAGE: +/-15V
* CONNECTIONS:   NON-INVERTING INPUT
*                | INVERTING INPUT
*                | | POSITIVE POWER SUPPLY
*                | | | NEGATIVE POWER SUPPLY
*                | | | | OUTPUT
*                | | | | |  COMPENSATION
*                | | | | | / \
.SUBCKT NE5534   1 2 3 4 5
*
  C1   11 12 7.703E-12
  DC    5 53 DX
  DE   54  5 DX
  DLP  90 91 DX
  DLN  92 90 DX
  DP    4  3 DX
  EGND 99  0 POLY(2) (3,0) (4,0) 0 .5 .5
  FB    7 99 POLY(5) VB VC VE VLP VLN 0 2.893E6 -3E6 3E6 3E6 -3E6
  GA    6  0 11 12 1.382E-3
  GCM   0  6 10 99 13.82E-9
  IEE  10  4 DC 133.0E-6
  HLIM 90  0 VLIM 1K
  Q1   11  2 13 QX
  Q2   12  1 14 QX
  R2    6  9 100.0E3
  RC1   3 11 723.3
  RC2   3 12 723.3
  RE1  13 10 329
  RE2  14 10 329
  REE  10 99 1.504E6
  RO1   8  5 50
  RO2   7 99 25
  RP    3  4 7.757E3
  VB    9  0 DC 0
  VC    3 53 DC 2.700
  VE   54  4 DC 2.700
  VLIM  7  8 DC 0
  VLP  91  0 DC 38
  VLN   0 92 DC 38
.MODEL DX D(IS=800.0E-18)
.MODEL QX NPN(IS=800.0E-18 BF=132)
.ENDS

Answer 1

X1 Vin_p Vin_n Vout Vdd Vss NE5534

相提并论

.SUBCKT NE5534   1 2 3 4 5

从模特那里。在模型中，节点5是输出。所以

X1 Vin_p Vin_n Vdd Vss Vout NE5534

都是对的。

该模型在+15/-15V电源电压下是有效的。+36/-36可能很难(我没有检查数据表)。请也检查一下电路。

在ngspice论坛(https://sourceforge.net/p/ngspice/discussion/133842/)上发布这样一个问题可能会在最迟几个小时内触发一个答案，而不是三个月后的偶然结果。