文章/答案/技术大牛

发布

社区首页 >问答首页 >未通过过程执行获得正确的输出

问未通过过程执行获得正确的输出
EN

Stack Overflow用户

提问于 2019-09-22 07:41:59

回答 1查看 48关注 0票数 0

我正在为下表(Sample_table)编写一个递归过程:考虑每一列都有varchar2数据类型：

PARENT_DATA CHILD_DATA  PARENT_VERSION  CHILD_VERSION
----------------------------------------------------------------
20-10       40-01       -A11            -A11
20-10       40-02       -A11            -A11
20-10       40-03       -A11            -A11
20-10       80-10       -A11            -A11
20-10       81-10       -A11            -A11
80-10       40-100      -A11            -A11
80-10       40-101      -A11            -A11
80-10       40-102      -A11            -A11

我需要编写一个递归过程，这样对于给定的PARENT_DATA，如果CHILD_DATA以'40‘开头，那么它将被打印出来。如果CHILD_DATA以'80‘开头，则该过程将被递归调用。最终输出如下所示：

PARENT_DATA CHILD_DATA PARENT_VERSION CHILD_VERSION
---------------------------------------------------
20-10       40-01       -A11        -A11
20-10       40-02       -A11        -A11
20-10       40-03       -A11        -A11
80-10       40-100      -A11        -A11
80-10       40-101      -A11        -A11
80-10       40-102      -A11        -A11

我尝试过使用cursor进行递归过程调用：

代码如下：

create or replace procedure proc_repeat(in_parent         in  varchar2,
                                        IN_VERSION        IN  VARCHAR2,
                                        out_child         out varchar2,
                                        OUT_CHILD_VERSION OUT VARCHAR2)
as
  v_parent_Data varchar2(50);
  v_data varchar2(50);
  v_data_VERSION varchar2(50);
  v_data_RECUR varchar2(50);
  v_data_RECUR_VERSION varchar2(50);

  cursor cur_data is 
    select parent_data,child_data,child_version
      from sample_table
      where parent_data = in_parent AND
            parent_version = IN_VERSION;
begin
  open cur_data;
  loop
    fetch cur_data
      into v_parent_Data,v_data,v_data_VERSION;

    exit when cur_data%notfound;

    IF V_DATA LIKE '40-%' THEN
      OUT_CHILD:=V_DATA;
      OUT_CHILD_VERSION:=v_data_VERSION;
    ELSIF V_DATA LIKE '80-%' THEN
      v_data_RECUR:=V_DATA;
      v_data_RECUR_VERSION:=v_data_VERSION;

      proc_repeat(v_data_RECUR, v_data_RECUR_VERSION,
                  out_child, OUT_CHILD_VERSION);
    END IF;
  end loop;

  close cur_Data;
end;

预期的结果是：

CHILD_DATA
-----------
40-01
40-02
40-03
40-100
40-101
40-102

但我只得到了'40-102‘

DECLARE
  A VARCHAR2(50):='20-10';
  B VARCHAR2(50):='-A11';
  C VARCHAR2(50);
  D VARCHAR2(50);
BEGIN
  proc_repeat(A,B,C,D);
  DBMS_OUTPUT.PUT_LINE(C);
END;

oracle

plsql

回答 1

Stack Overflow用户

发布于 2019-09-23 05:25:15

让我们通过添加一些DBMS_OUTPUT.PUT_LINE调用来创建过程的仪表化版本。这看起来像这样：

create or replace procedure proc_repeat_I1(in_parent         in  varchar2,
                                           IN_VERSION        IN  VARCHAR2,
                                           out_child         out varchar2,
                                           OUT_CHILD_VERSION OUT VARCHAR2)
as
  v_parent_Data varchar2(50);
  v_data varchar2(50);
  v_data_VERSION varchar2(50);
  v_data_RECUR varchar2(50);
  v_data_RECUR_VERSION varchar2(50);

  cursor cur_data is 
    select parent_data,child_data,child_version
      from sample_table
      where parent_data = in_parent AND
            parent_version = IN_VERSION;
begin
  DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I1 : START - IN_PARENT=' || IN_PARENT ||
                                    ' IN_VERSION=' || IN_VERSION ||
                                    ' OUT_CHILD=' || OUT_CHILD);

  open cur_data;
  loop
    fetch cur_data
      into v_parent_Data,v_data,v_data_VERSION;

    exit when cur_data%notfound;

    DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I1 : v_parent_Data=' || v_parent_Data ||
                                      ' v_data=' || v_data);

    IF V_DATA LIKE '40-%' THEN
      OUT_CHILD:=V_DATA;
      OUT_CHILD_VERSION:=v_data_VERSION;

      DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = ' || OUT_CHILD);
    ELSIF V_DATA LIKE '80-%' THEN
      v_data_RECUR:=V_DATA;
      v_data_RECUR_VERSION:=v_data_VERSION;

      DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I1 : BLOCK 2 : OUT_CHILD = ' || OUT_CHILD ||
                           ' V_DATA_RECUR = ' || V_DATA_RECUR);

      proc_repeat_I(v_data_RECUR, v_data_RECUR_VERSION,
                    out_child, OUT_CHILD_VERSION);
    END IF;
  end loop;

  close cur_Data;

  DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I1 : EXIT');
end;

当我们运行此命令时，输出为：

PROC_REPEAT_I1 : START - IN_PARENT=20-10 IN_VERSION=-A11 OUT_CHILD=
PROC_REPEAT_I1 : v_parent_Data=20-10 v_data=40-01
PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = 40-01
PROC_REPEAT_I1 : v_parent_Data=20-10 v_data=40-02
PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = 40-02
PROC_REPEAT_I1 : v_parent_Data=20-10 v_data=40-03
PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = 40-03
PROC_REPEAT_I1 : v_parent_Data=20-10 v_data=80-10
PROC_REPEAT_I1 : BLOCK 2 : OUT_CHILD = 40-03 V_DATA_RECUR = 80-10
PROC_REPEAT_I1 : START - IN_PARENT=80-10 IN_VERSION=-A11 OUT_CHILD=
PROC_REPEAT_I1 : v_parent_Data=80-10 v_data=40-100
PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = 40-100
PROC_REPEAT_I1 : v_parent_Data=80-10 v_data=40-101
PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = 40-101
PROC_REPEAT_I1 : v_parent_Data=80-10 v_data=40-102
PROC_REPEAT_I1 : BLOCK 1 : OUT_CHILD = 40-102
PROC_REPEAT_I1 : EXIT
PROC_REPEAT_I1 : v_parent_Data=20-10 v_data=81-10
PROC_REPEAT_I1 : EXIT
40-102

我们可以看到，从匿名块对该过程进行了第一次调用，将'20-10'作为父版本传递，'-A11'作为父版本传递，然后游标遍历'40-01‘、'40-02'和'40-03'，直到到达'80-10'。一旦它到达'80-20'，它就转到第二个块，递归地调用自己，然后像预期的那样遍历'40-100'、'40-101'和'40-102'。

那么这里出了什么问题呢？好吧，什么都没有--除了您的代码不会导致游标中的值累积到OUT_CHILD中，或者打印出来。因此，让我们更改我们的仪表化版本，将游标返回的值累积到OUT_CHILD中

create or replace procedure proc_repeat_I2(in_parent         in  varchar2,
                                           IN_VERSION        IN  VARCHAR2,
                                           out_child         out varchar2,
                                           OUT_CHILD_VERSION OUT VARCHAR2)
as
  v_parent_Data varchar2(50);
  v_data varchar2(50);
  v_data_VERSION varchar2(50);
  v_data_RECUR varchar2(50);
  v_data_RECUR_VERSION varchar2(50);

  cursor cur_data is 
    select parent_data,child_data,child_version
      from sample_table
      where parent_data = in_parent AND
            parent_version = IN_VERSION;
begin
  DBMS_OUTPUT.PUT_LINE('PROC_REPEAT : START - IN_PARENT=' || IN_PARENT ||
                                    ' IN_VERSION=' || IN_VERSION ||
                                    ' OUT_CHILD=' || OUT_CHILD);

  open cur_data;
  loop
    fetch cur_data
      into v_parent_Data,v_data,v_data_VERSION;

    exit when cur_data%notfound;

    DBMS_OUTPUT.PUT_LINE('PROC_REPEAT : v_parent_Data=' || v_parent_Data ||
                                      ' v_data=' || v_data);

    IF V_DATA LIKE '40-%' THEN
      OUT_CHILD := CASE
                     WHEN OUT_CHILD IS NULL THEN OUT_CHILD
                     ELSE OUT_CHILD || ', '
                   END || V_DATA;
      OUT_CHILD_VERSION := CASE
                             WHEN OUT_CHILD_VERSION IS NULL THEN OUT_CHILD_VERSION
                             ELSE OUT_CHILD_VERSION || ', '
                           END || V_DATA_VERSION;

      DBMS_OUTPUT.PUT_LINE('BLOCK 1 : OUT_CHILD = ' || OUT_CHILD);
    ELSIF V_DATA LIKE '80-%' THEN
      v_data_RECUR:=V_DATA;
      v_data_RECUR_VERSION:=v_data_VERSION;

      DBMS_OUTPUT.PUT_LINE('BLOCK 2 : OUT_CHILD = ' || OUT_CHILD ||
                           ' V_DATA_RECUR = ' || V_DATA_RECUR);

      proc_repeat_I2(v_data_RECUR, v_data_RECUR_VERSION,
                     out_child, OUT_CHILD_VERSION);
    END IF;
  end loop;

  close cur_Data;

  DBMS_OUTPUT.PUT_LINE('PROC_REPEAT : EXIT');
end;

但是这仍然是不正确的！下面是输出：

PROC_REPEAT_I2 : START - IN_PARENT=20-10 IN_VERSION=-A11 OUT_CHILD=
PROC_REPEAT_I2 : v_parent_Data=20-10 v_data=40-01
PROC_REPEAT_I2 : BLOCK 1 : OUT_CHILD = 40-01
PROC_REPEAT_I2 : v_parent_Data=20-10 v_data=40-02
PROC_REPEAT_I2 : BLOCK 1 : OUT_CHILD = 40-01, 40-02
PROC_REPEAT_I2 : v_parent_Data=20-10 v_data=40-03
PROC_REPEAT_I2 : BLOCK 1 : OUT_CHILD = 40-01, 40-02, 40-03
PROC_REPEAT_I2 : v_parent_Data=20-10 v_data=80-10
PROC_REPEAT_I2 : BLOCK 2 : OUT_CHILD = 40-01, 40-02, 40-03 V_DATA_RECUR = 80-10
PROC_REPEAT_I2 : START - IN_PARENT=80-10 IN_VERSION=-A11 OUT_CHILD=
PROC_REPEAT_I2 : v_parent_Data=80-10 v_data=40-100
PROC_REPEAT_I2 : BLOCK 1 : OUT_CHILD = 40-100
PROC_REPEAT_I2 : v_parent_Data=80-10 v_data=40-101
PROC_REPEAT_I2 : BLOCK 1 : OUT_CHILD = 40-100, 40-101
PROC_REPEAT_I2 : v_parent_Data=80-10 v_data=40-102
PROC_REPEAT_I2 : BLOCK 1 : OUT_CHILD = 40-100, 40-101, 40-102
PROC_REPEAT_I2 : EXIT
PROC_REPEAT_I2 : v_parent_Data=20-10 v_data=81-10
PROC_REPEAT_I2 : EXIT
40-100, 40-101, 40-102

在这里我们可以看到父值似乎在累积，直到我们进入块2并递归调用PROC_REPEAT_I2，这时point...THEY就消失了！啊哈！发生了什么？！？

关于PL/SQL有一个有趣的事实--当您使用OUT参数调用例程时，OUT参数在过程开始时被设置为NULL。如果希望保留过程参数中已经存在的值，则需要将参数定义为IN OUT而不是OUT。所以我们得到了这个过程的第三个版本：

create or replace procedure PROC_REPEAT_I3(in_parent         in  varchar2,
                                           IN_VERSION        IN  VARCHAR2,
                                           out_child         IN OUT varchar2,
                                           OUT_CHILD_VERSION IN OUT VARCHAR2)
as
  v_parent_Data varchar2(50);
  v_data varchar2(50);
  v_data_VERSION varchar2(50);
  v_data_RECUR varchar2(50);
  v_data_RECUR_VERSION varchar2(50);

  cursor cur_data is 
    select parent_data,child_data,child_version
      from sample_table
      where parent_data = in_parent AND
            parent_version = IN_VERSION;
begin
  DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I3 : START - IN_PARENT=' || IN_PARENT ||
                                    ' IN_VERSION=' || IN_VERSION ||
                                    ' OUT_CHILD=' || OUT_CHILD);

  open cur_data;
  loop
    fetch cur_data
      into v_parent_Data,v_data,v_data_VERSION;

    exit when cur_data%notfound;

    DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I3 : v_parent_Data=' || v_parent_Data ||
                                      ' v_data=' || v_data);

    IF V_DATA LIKE '40-%' THEN
      OUT_CHILD := CASE
                     WHEN OUT_CHILD IS NULL THEN OUT_CHILD
                     ELSE OUT_CHILD || ', '
                   END || V_DATA;
      OUT_CHILD_VERSION := CASE
                             WHEN OUT_CHILD_VERSION IS NULL THEN OUT_CHILD_VERSION
                             ELSE OUT_CHILD_VERSION || ', '
                           END || V_DATA_VERSION;

      DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = ' || OUT_CHILD);
    ELSIF V_DATA LIKE '80-%' THEN
      v_data_RECUR:=V_DATA;
      v_data_RECUR_VERSION:=v_data_VERSION;

      DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I3 : BLOCK 2 : OUT_CHILD = ' || OUT_CHILD ||
                           ' V_DATA_RECUR = ' || V_DATA_RECUR);

      proc_repeat_I3(v_data_RECUR, v_data_RECUR_VERSION,
                  out_child, OUT_CHILD_VERSION);
    END IF;
  end loop;

  close cur_Data;

  DBMS_OUTPUT.PUT_LINE('PROC_REPEAT_I3 : EXIT');
end;

这个版本的输出如下所示：

PROC_REPEAT_I3 : START - IN_PARENT=20-10 IN_VERSION=-A11 OUT_CHILD=
PROC_REPEAT_I3 : v_parent_Data=20-10 v_data=40-01
PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = 40-01
PROC_REPEAT_I3 : v_parent_Data=20-10 v_data=40-02
PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = 40-01, 40-02
PROC_REPEAT_I3 : v_parent_Data=20-10 v_data=40-03
PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = 40-01, 40-02, 40-03
PROC_REPEAT_I3 : v_parent_Data=20-10 v_data=80-10
PROC_REPEAT_I3 : BLOCK 2 : OUT_CHILD = 40-01, 40-02, 40-03 V_DATA_RECUR = 80-10
PROC_REPEAT_I3 : START - IN_PARENT=80-10 IN_VERSION=-A11 OUT_CHILD=40-01, 40-02, 40-03
PROC_REPEAT_I3 : v_parent_Data=80-10 v_data=40-100
PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = 40-01, 40-02, 40-03, 40-100
PROC_REPEAT_I3 : v_parent_Data=80-10 v_data=40-101
PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = 40-01, 40-02, 40-03, 40-100, 40-101
PROC_REPEAT_I3 : v_parent_Data=80-10 v_data=40-102
PROC_REPEAT_I3 : BLOCK 1 : OUT_CHILD = 40-01, 40-02, 40-03, 40-100, 40-101, 40-102
PROC_REPEAT_I3 : EXIT
PROC_REPEAT_I3 : v_parent_Data=20-10 v_data=81-10
PROC_REPEAT_I3 : EXIT
40-01, 40-02, 40-03, 40-100, 40-101, 40-102

最后，给出正确的结果。

所以，记住-当事情不起作用时，试着打印出中间结果，这样你就可以看到发生了什么。

dbfiddle here

票数 0

页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持

原文链接：

https://stackoverflow.com/questions/58044956

复制

相似问题

问未通过过程执行获得正确的输出
EN

回答 1

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问未通过过程执行获得正确的输出EN

回答 1

Stack Overflow用户

社区

活动

圈层

关于

腾讯云开发者

热门产品

热门推荐

更多推荐

问未通过过程执行获得正确的输出
EN