excel的数值调节按钮

Question

我正在尝试添加一个旋转按钮，以便在任何存在数据的地方递增一个值。

我手动为一个字段添加了一个旋转按钮来递增该值。如何在有值的地方添加旋转按钮。就像购物车一样。

Private Sub quantity_SpinDown()
   Range("M6").Value = Range("M6") - 1

End Sub

Private Sub quantity_SpinUp()
Range("M6").Value = Range("M6") + 1

End Sub

我期待这个旋转按钮，只要购物车中有商品出现，它就会增加购物车中商品的价值。Check Image here

Answer 1

可以创建宏来动态创建微调器。在下面的示例中，您可以选择工作表中的一些单元格，然后执行以下Sub

Option Explicit

Sub createSpinnersInSelection()

    Dim spinner As OLEObject
    Dim selectedCell As Range

    For Each selectedCell In Selection
        ' Creates a spinner
        Set spinner = selectedCell.Parent.OLEObjects.Add(ClassType:="Forms.SpinButton.1", Top:=selectedCell.Top, Left:=selectedCell.Left, Height:=selectedCell.RowHeight, Width:=15)

        ' Setting spinner properties
        With spinner
            ' Cell to change the value
            .LinkedCell = selectedCell.Address(0, 0)
            With .Object
                ' Initial value
                .Value = 0
                ' Increment of cell
                .SmallChange = 1
            End With
        End With
    Next selectedCell

End Sub

您可以添加更多属性，如微调器颜色和其他属性(代码改编自此thread)

重要提示：您可能需要稍微调整.LinkedCell的值，因为当您筛选列时，它可能会保留原始单元格引用，并在不同于预期单元格的单元格中更改值。