VBA和OneNote。在另一节中移动页面: OneNote.UpdateContentPage方法出错

Question

我写了一个子例程，将页面移动到与原始页面不同的部分，但它不起作用！有人能帮帮我吗？

Private Sub CreateInNewSection(onote As OneNote.Application, pageXML As String, newSecId As String, title As String)

    Dim pDoc As MSXML2.DOMDocument60
    Set pDoc = New MSXML2.DOMDocument60
    If pDoc.LoadXML(pageXML) Then
        Dim cNodes As MSXML2.IXMLDOMNodeList
        Dim fNodes As MSXML2.IXMLDOMNodeList
        Dim iNodes As MSXML2.IXMLDOMNodeList
        Dim cNode As MSXML2.IXMLDOMNode
        Dim fNode As MSXML2.IXMLDOMNode
        Dim iNode As MSXML2.IXMLDOMNode
        soapNS = "xmlns:one='http://schemas.microsoft.com/office/onenote/2013/onenote'"
        pDoc.setProperty "SelectionNamespaces", soapNS
        Set cNodes = pDoc.DocumentElement.SelectNodes("//one:T")
        Set fNodes = pDoc.DocumentElement.SelectNodes("//one:InsertedFile")
        Set iNodes = pDoc.DocumentElement.SelectNodes("//one:Image")
        Dim nPageID As String
        onote.CreateNewPage newSecId, nPageID, npsDefault
        Dim oXML As String
        onote.GetPageContent nPageID, oXML, piAll, xs2013

        'oXML = pageXML
        Dim nDoc As MSXML2.DOMDocument60
        Set nDoc = New MSXML2.DOMDocument60
        If nDoc.LoadXML(oXML) Then
            Dim npNode As MSXML2.IXMLDOMNode
            soapNS = "xmlns:one='http://schemas.microsoft.com/office/onenote/2013/onenote'"
            nDoc.setProperty "SelectionNamespaces", soapNS
            Set npNode = nDoc.SelectSingleNode("//one:Page")

            ' Find the Title element.
            Dim tNode As MSXML2.IXMLDOMNode
            Set tNode = nDoc.SelectSingleNode("//one:Page/one:Title/one:OE/one:T")

            ' Get the CDataSection where OneNote store's the Title's text.
            Dim cdataChild As MSXML2.IXMLDOMNode
            Set cdataChild = tNode.SelectSingleNode("text()")

            ' Change the title in the local XML copy.
            cdataChild.Text = title
            ' Write the update to OneNote.
            'oneNote.UpdatePageContent doc.XML

            '---------- For Text Nodes -----------

            For Each cNode In cNodes
                If cNode.Text <> "" Then
                    Dim newTextNodeElement As MSXML2.IXMLDOMElement
                    Dim newTextNode As MSXML2.IXMLDOMNode
                    ' Create Outline node.
                    Set newTextNodeElement = nDoc.createElement("one:Outline")
                    Set newTextNode = npNode.appendChild(newTextNodeElement)
                    ' Create OEChildren.
                    Set newTextNodeElement = nDoc.createElement("one:OEChildren")
                    Set newTextNode = newTextNode.appendChild(newTextNodeElement)
                    ' Create OE.
                    Set newTextNodeElement = nDoc.createElement("one:OE")
                    Set newTextNode = newTextNode.appendChild(newTextNodeElement)
                    ' Create TE.
                    Set newTextNodeElement = nDoc.createElement("one:T")
                    Set newTextNode = newTextNode.appendChild(newTextNodeElement)

                    ' Add the text for the Page's content.
                    Dim newcd As MSXML2.IXMLDOMCDATASection
                    Set newcd = nDoc.createCDATASection(cNode.Text)
                    newTextNode.appendChild newcd
                End If
            Next

                    ---------- For File Nodes -----------

            For Each fNode In fNodes

                'Set newFileNode = fNode
                Set npNode = npNode.appendChild(fNode)

            Next

            onote.UpdatePageContent nDoc.XML, DateTime.Now, xs2013

        End If
    End If

End Sub

onenote.UpdatePageContent继续失败，并显示运行时错误-2147213296 (80042010)。如果我只考虑文本节点，代码就可以工作，而如果我为文件节点添加代码，它就不能再工作了。

我尝试使用以下代码更改文件节点的代码：

For Each fNode In fNodes            

    Dim newFileNodeElement As MSXML2.IXMLDOMElement
    Dim newFileNode As MSXML2.IXMLDOMNode

    'Set newFileNode = fNode
    'Set npNode = npNode.appendChild(fNode)

    Set newFileNodeElement = nDoc.createElement("one:InsertedFile")
    Set newFileNode = npNode.appendChild(newFileNodeElement)

    For i = 0 To fNode.Attributes.Length - 1
        Dim attrName As String
        Dim attrValue As String
        Dim attr As MSXML2.IXMLDOMAttribute
        Dim namedNodeMap As MSXML2.IXMLDOMNamedNodeMap

        attrName = fNode.Attributes(i).nodeName
        attrValue = fNode.Attributes(i).NodeValue
        Set attr = nDoc.createNode(2, attrName, "")
        attr.Value = attrValue

        Set namedNodeMap = nDoc.DocumentElement.LastChild.Attributes
        Set newFileNode = namedNodeMap.setNamedItem(attr)


    Next i      
Next

但是结果是一样的。

Answer 1

here列出了OneNote错误代码，因此错误是“上次修改日期不匹配。”。

UpdatePageContent的第二个参数是：

dateExpectedLastModified -(可选)您认为上次修改要更新的页面的日期和时间。如果为此参数传递一个非零值，则仅当传递的值与上次修改页面的实际日期和时间匹配时，OneNote才会继续更新。传递此参数的值有助于防止意外覆盖用户自上次修改页面以来所做的编辑。

如果您不需要DateTime.Now参数(省略它)，请删除它，或者更正值。它是一个附加的检查参数，而不是日期戳。

Answer 2

我用一种不同的方法解决了这个问题:我使用Publish方法来创建一个新的部分，使用我需要复制的页面的名称来创建一个新的部分，使用MergeSections方法来复制我想要复制的部分中的页面。代码如下：

Private Sub CreateInNewSection(onote As onenote.Application, pageXML As String, 
newSecId As String, title As String, nbID As String, path As String)

Dim pDoc As MSXML2.DOMDocument60
Set pDoc = New MSXML2.DOMDocument60
If pDoc.LoadXML(pageXML) Then
    Dim pNode As MSXML2.IXMLDOMNode
    soapNS = "xmlns:one='http://schemas.microsoft.com/office/onenote/2013/onenote'"
    pDoc.setProperty "SelectionNamespaces", soapNS
    Set pNode = pDoc.SelectSingleNode("//one:Page")
    Dim oldPageId As String
    Dim oldPageName As String
    oldPageId = pNode.Attributes.getNamedItem("ID").Text
    oldPageName = pNode.Attributes.getNamedItem("name").Text
    path = path + "\" + oldPageName + ".one"
    Debug.Print path

    onote.Publish oldPageId, path, pfOneNote, ""

    Dim sXml As String
    onote.GetHierarchy nbID, hsSections, sXml, xs2013
    Dim sDoc As MSXML2.DOMDocument60
    Set sDoc = New MSXML2.DOMDocument60
    Dim nowSecId As String

    If sDoc.LoadXML(sXml) Then
        ' select the Section nodes
        Dim sNodes As MSXML2.IXMLDOMNodeList
        soapNS = "xmlns:one='http://schemas.microsoft.com/office/onenote/2013/onenote'"
        sDoc.setProperty "SelectionNamespaces", soapNS
        Set sNodes = sDoc.DocumentElement.SelectNodes("//one:Section")

        Dim j As Integer
        If Not sNodes Is Nothing Then
            ' Get the first section.
            Dim sNode As MSXML2.IXMLDOMNode
            For j = 0 To (sNodes.Length - 1)
                If sNodes(j).Attributes.getNamedItem("name").Text = oldPageName Then
                    nowSecId = sNodes(j).Attributes.getNamedItem("ID").Text
                    Exit For
                End If
            Next j
        End If
        onote.MergeSections nowSecId, newSecId
        onote.DeleteHierarchy nowSecId
        onote.DeleteHierarchy oldPageId
    End If
End If

End Sub