在windows上安装Lua时出错

Question

我下载了LuaV5.3.0、编译器和Zip-7，并将所有内容保存在C:\\gcc-install-lua目录中，打开记事本，并在下面的代码中写道：

@echo off
    :: ========================
    :: file build.cmd
    :: ========================
    setlocal
    :: you may change the following variable's value
    :: to suit the downloaded version
    set lua_version=5.3.0

    set work_dir=%~dp0
    :: Removes trailing backslash
    :: to enhance readability in the following steps
    set work_dir=%work_dir:~0,-1%
    set lua_install_dir=%work_dir%\lua
    set compiler_bin_dir=%work_dir%\tdm-gcc\bin
    set lua_build_dir=%work_dir%\lua-%lua_version%
    set path=%compiler_bin_dir%;%path%

    cd /D %lua_build_dir%
    mingw32-make PLAT=mingw

    echo.
    echo **** COMPILATION TERMINATED ****
    echo.
    echo **** BUILDING BINARY DISTRIBUTION ****
    echo.

    :: create a clean "binary" installation
    mkdir %lua_install_dir%
    mkdir %lua_install_dir%\doc
    mkdir %lua_install_dir%\bin
    mkdir %lua_install_dir%\include

    copy %lua_build_dir%\doc\*.* %lua_install_dir%\doc\*.*
    copy %lua_build_dir%\src\*.exe %lua_install_dir%\bin\*.*
    copy %lua_build_dir%\src\*.dll %lua_install_dir%\bin\*.*
    copy %lua_build_dir%\src\luaconf.h %lua_install_dir%\include\*.*
    copy %lua_build_dir%\src\lua.h %lua_install_dir%\include\*.*
    copy %lua_build_dir%\src\lualib.h %lua_install_dir%\include\*.*
    copy %lua_build_dir%\src\lauxlib.h %lua_install_dir%\include\*.*
    copy %lua_build_dir%\src\lua.hpp %lua_install_dir%\include\*.*

    echo.
    echo **** BINARY DISTRIBUTION BUILT ****
    echo.

    %lua_install_dir%\bin\lua.exe -e"print [[Hello!]];print[[Simple Lua test successful!!!]]"

    echo.

    pause

并在目录中另存为cmd文件，现在我想在命令行中运行build.cmd，但我在Cmd中给出了这个错误

​

并且在Lua文件中创建的bin子目录中没有lua.exe文件后，我该如何修复呢？

Answer 1

如何在Windows下构建Lua (适用于虚拟对象)

这种方法可能不适用于OP的情况，但构建Lua for Windows的最简单方法是使用Visual Studio (我假设您已经在PC上安装了它)。

您需要创建新的文件luavs.bat并在其中填充内容(如下所示)

cd /d full\path\to\lua-5.3.4
notepad luavs.bat

现在你的lua distrib文件夹应该如下所示：

lua-5.3.4
 |___src
 |    |...
 |___doc
 |    |...
 |___Makefile
 |___README
 |___luavs.bat

您不能直接运行luavs.bat，而是从Visual Studio命令提示符(在“开始”菜单下的“所有程序”中搜索)。

在出现以下行之后：

Setting environment for using Microsoft Visual Studio 2010 x86 tools.
C:\Program Files (x86)\Microsoft Visual Studio 10.0\VC>

输入以下命令：

cd /d full\path\to\lua-5.3.4
luavs.bat
mkdir C:\Lua
copy /y src\lua53.exe C:\Lua
copy /y src\lua53.dll C:\Lua
copy /y src\luac53.exe C:\Lua
mkdir C:\Lua\lua

现在，将文件夹C:\Lua添加到PATH环境变量(控制面板-> System ->高级->环境变量)的开头。

您现在可以使用lua53命令运行Lua。

文件夹C:\Lua\lua用于Lua模块。

luavs.bat的内容

@rem Script to build Lua 5.3 under "Visual Studio .NET Command Prompt".
@rem It creates lua53.dll, lua53.lib, lua53.exe, and luac53.exe in src.
@rem (contributed by David Manura and Mike Pall)

@setlocal
@set VERS=53
@set MYCOMPILE=cl /nologo /MD /O2 /W3 /c /D_CRT_SECURE_NO_DEPRECATE
@set MYLINK=link /nologo
@set MYMT=mt /nologo

cd src
%MYCOMPILE% /DLUA_BUILD_AS_DLL l*.c
del lua.obj luac.obj
%MYLINK% /DLL /out:lua%VERS%.dll l*.obj
%MYCOMPILE% /DLUA_BUILD_AS_DLL lua.c
%MYLINK% /out:lua%VERS%.exe lua.obj lua%VERS%.lib
%MYCOMPILE% l*.c
del lua.obj linit.obj lbaselib.obj ldblib.obj liolib.obj lmathlib.obj loslib.obj ltablib.obj lstrlib.obj loadlib.obj
%MYLINK% /out:luac%VERS%.exe *.obj
del *.obj
cd ..