不同值的排序序列

Question

要对从distinct-values()获得的序列进行排序，最干净的方法是什么？我使用的是XPath 2.0，我的文件如下：

这是我的XML文件

<root>
  <value>3</value>
  <value>1</value>
  <value>7</value>
</root>

这就是我的转变：

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes"/>

  <xsl:template match="root">
    <output>
      <xsl:variable name="availableValues" select="distinct-values(value)"/>
      <!-- now the availableValues contains the sequence (3,1,7) -->
      <!-- My goal is to get this into a sorted sequence (1,3,7) -->


      <!-- This is just for testing the $availableValues -->
      <xsl:attribute name="count" select="count($availableValues)"/>
      <xsl:for-each select="$availableValues">
        <val>
          <xsl:value-of select="."/>
        </val>
      </xsl:for-each>
    </output>
  </xsl:template>
</xsl:stylesheet>

我试着用

  <xsl:variable name="availableValues">
    <xsl:for-each select="distinct-values(value)">
      <xsl:sort/>
      <xsl:value-of select="."/>
    </xsl:for-each>
  </xsl:variable>

但是这(当然)没有给我一个序列，只是值的连接(尽管是排序的)。

编辑：

这就是我到目前为止想出来的，它看起来是一个合适的解决方案。有没有更好的解决方案？

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  >
  <xsl:output indent="yes"/>

  <xsl:template match="root">
    <output>
      <xsl:variable name="availableValues" as="xs:integer *">
        <xsl:for-each select="distinct-values(value)">
          <xsl:sort/>
          <xsl:sequence select="."/>
        </xsl:for-each>    
      </xsl:variable>

      <!-- This is just for testing the $availableValues -->
      <xsl:attribute name="count" select="count($availableValues)"/>
      <xsl:for-each select="$availableValues">
        <val>
          <xsl:value-of select="."/>
        </val>
      </xsl:for-each>
    </output>
  </xsl:template>
</xsl:stylesheet>

Answer 1

使用xsl:perform-sort。

以下是链接中的一个示例：

<xsl:perform-sort select="//BOOK">
    <xsl:sort select="author/last-name"/>
    <xsl:sort select="author/first-name"/>
</xsl:perform-sort>