首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >Excel宏单列转置为两列

问Excel宏单列转置为两列
EN

Stack Overflow用户
提问于 2017-04-21 02:47:15
回答 2查看 21关注 0票数 0

我已经创建了以下宏

我的数据一直到主数据表中的第3710行--但我不知道如何强制这个宏循环并包含所有数据

代码语言:javascript
复制
Sub Macro3()
'
' Macro3 Macro
'

'
    Range("A1:A2").Select
    Selection.Copy
    Sheets("Sheet2").Select
    Range("A1:B1").Select
    Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
        False, Transpose:=True
    Sheets("Sheet1").Select
    Range("A3:A4").Select
    Application.CutCopyMode = False
    Selection.Copy
    Sheets("Sheet2").Select
    Range("A2:B2").Select
    Selection.PasteSpecial Paste:=xlPasteAll, Operation:=xlNone, SkipBlanks:= _
    False, Transpose:=True
End Sub
EN

回答 2

Stack Overflow用户

发布于 2017-04-21 03:14:40

您可以使用for循环来完成此操作。此外,在VBA以及.SELECT和.ACtivate中,复制/粘贴也是我们通常回避的东西。这些都是人类执行的功能,但计算机只能将单元格设置为等于其他单元格的值,例如:

代码语言:javascript
复制
 Sheets("Sheet1").Cells(1, 1).value = Sheets("Sheet2").Cells(1,1).value

这说明Sheet1中的单元格"A1“应该设置为Sheet2单元格"A1”中的任何值。

改变周围的情况,实现一个循环来执行转置,并使用一些快速的线性回归公式来确定写入到哪一行:

代码语言:javascript
复制
Sub wierdTranspose()
    'Loop from row 1 to row 3710, but every other row
    For i = 1 to 3710 Step 2    
        'Now we select from row i and row i + 1  (A1 and A2, then A3 and A4, etc)
        'And we put that value in the row of sheet2 that corresponds to (.5*i)+.5
        '   So if we are picking up from Rows 7 and 8, "i" will be 7 and (.5*i)+.5 will be row 4 that we paste to
        '   Then the next iteration will be row 9 and 10, so "i" will be 9 and (.5*i)+.5 will be row 5 that we paste to 
        '   and on and on until we hit 3709 and 3710...
        Sheets("Sheet2").Cells((.5*i)+.5, 1).value = Sheets("Sheet1").Cells(i, 1).value
        Sheets("Sheet2").Cells((.5*i)+.5, 2).value = Sheets("Sheet1").Cells(i+1, 1).value
    Next i
End Sub
票数 0
EN

Stack Overflow用户

发布于 2017-04-21 03:18:25

最好通过VBA阵列传输批量数据,无需复制/粘贴。

如下所示:

代码语言:javascript
复制
Sub SplitColumn()
    Dim A As Variant, B As Variant
    Dim i As Long
    Dim ws1 As Worksheet, ws2 As Worksheet

    Set ws1 = Sheets(1)
    Set ws2 = Sheets(2)

    With ws1
        A = .Range(.Cells(1, 1), .Cells(3710, 1))
    End With

    ReDim B(1 To 1855, 1 To 2)
    For i = 1 To 1855
        B(i, 1) = A(2 * i - 1, 1)
        B(i, 2) = A(2 * i, 1)
    Next i

    With ws2
        .Range(.Cells(1, 1), .Cells(1855, 2)).Value = B
    End With

End Sub
票数 0
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/43527545

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档