首页
学习
活动
专区
圈层
工具
发布
社区首页 >问答首页 >旧版Visual Fox Pro应用程序中的非自动递增主键

问旧版Visual Fox Pro应用程序中的非自动递增主键
EN

Stack Overflow用户
提问于 2013-06-19 23:18:40
回答 3查看 291关注 0票数 0

首先,我想说我根本不能修改数据库模式。

我不能访问任何与数据库交互的现有代码。这是一个编译过的程序集,我不能反编译。

​

​

我有一个数据库表,其值在逻辑上充当代码中的主键,但不会自动递增。

这里有一个转折,有时关键是递增正数,有时是负数。:(

找不到任何希洛密码的证据。

我不知道如何处理这一点,除了选择前1名,添加一个值,并希望没有重叠发生。

EN

回答 3

Stack Overflow用户

回答已采纳

发布于 2013-06-20 01:13:37

如果您的表是数据库容器(*.DBC)的一部分,而不是空闲表,那么您可能会在数据库容器中找到自动递增键的代码。

如果打开表格并使用修改结构命令,则可以在第三个选项卡上看到表格的属性。如果该表是数据库容器的成员,则将显示该数据库的名称,以及触发器和记录规则在内的所有规则,该规则在每次写入该表时执行。

在添加自动递增字段之前,我通过添加记录规则实现了自动递增字段,如下所示:

代码语言:javascript
复制
PROCEDURE TABLE_RR
    LOCAL nOldArea,nUnique

    IF PK=0     &&Only update primary key field when not already set   
        STORE SELECT() TO nOldArea

        &&Open table again in another work area, we can't move the record pointer in a Rule
        IF !USED("TABLE_RR")
            USE TABLE.DBF IN 0 NOUPDATE AGAIN ALIAS TABLE_RR
        ENDIF

        &&Find current maximum value of primary key field, add 1 as next primary key field
        SELECT TABLE_RR
        SET ORDER TO PKTable
        GO BOTT
        STORE 1+PK TO nUnique

        &&Update primary key field for our record
        SELECT(nOldArea)
        REPLACE PK WITH nUnique

     ENDIF

     &&Record rule must return true or changes are rejected
     RETURN .T.

ENDPROC

将这样的规则存储在数据库容器存储过程代码区是正常的习惯和做法,但是,如果运行的应用程序可以找到该函数,它就会执行。显然,上面的代码示例假设该表名为TABLE,有一个名为PK的数值(Int更可取)字段,索引标记为PKTable。

因为代码在记录规则中,所以它在任何更新期间对记录执行,因此当记录被锁定时,因此没有冲突。任何在PK中没有值的记录都会得到1+该字段的当前最高值。记录规则用于验证记录并拒绝无效值,并且必须返回true (.T)。以使写入被接受。其他代码可能出现在该过程中,包括将当前值设置为时间戳字段等。

记录规则可以通过ALTER table命令应用于表:

代码语言:javascript
复制
ALTER TABLE 'TABLENAME' SET CHECK PROCEDURENAME()

或通过交互式表格编辑器修改结构

票数 2
EN

Stack Overflow用户

发布于 2013-06-20 00:17:17

不知道你需要什么,但如果你需要一个额外的PK,你可以使用记录号:

代码语言:javascript
复制
SELECT RECNO() FROM table1
票数 0
EN

Stack Overflow用户

发布于 2013-06-20 02:27:58

尽管Steve的解决方案非常好,特别是利用数据库容器和分配规则,但您显然(在某种程度上)卡在了您的情况下。如果您正在尝试添加记录,并且需要创建您自己的自动增量,则可能只需通过一个过程调用并分配它即可。这只是一个例子,但可能会对您有所帮助。

代码语言:javascript
复制
FUNCTION AddMyNewRecord()
   */ localized variable so you don't accidentally mangle some otherwise 
   */ coincidental variable somewhere else.  Preserve work area at start
   local lnSelect, llSaveOk, lnAttempts, lnNewPKID
   lnSelect = select()
   llSaveOk = .f.    

   select YourAddressTable
   if NOT FLOCK()
      lnAttempts = 0
      do while lnAttempts < 10 AND NOT FLOCK()
         wait window "Attempting lock for address table..." timeout 1
      enddo
   endif 

   if NOT FLOCK()
      messagebox( "Unable to lock file to add next record primary key." )
   else
      */ We have a lock, now try to detect both the highest and lowest
      */ EXISTING key for the table
      use in select( "C_TryNextKey" )
      select MIN( YAT.PK ) as MinKey,;
             MAX( YAT.PK ) as MaxKey ;
         from ;
            YourAddressTable YAT;
         into ;
            cursor C_TryNextKey readwrite 

      */ Determine if you need higher or lower key sequence
      if CriteriaForPositiveKey
         lnNewPKID = C_TryNextKey.MaxKey +1
      else
         */ must be getting next LOWER sequence
         lnNewPKID = C_TryNextKey.MinKey -1
      endif 

      */ close temp cursor from getting respective high / low key
      use in select( "C_TryNextKey" )

      */ NOW, we can add the new record
      Select YourAddressTable
      APPEND BLANK
      */ replace PK and all the other fields you need to do too
      Replace PK with lnNewPKID,;
              Address1 with lcSomeVariableYouHaveForAddress1,;
              Address2 with lcSomeVariableForAddress2,;
              AnyOtherFields with lcOtherFieldsToBeSet

      */ Unlock the address table
      UNLOCK

      */ set flag so we know it worked vs not.
      llSaveOk = .t.
   endif  

   */ Return back where it started
   select( lnSelect )

   */ Return if the save was ok or not.
   return llSaveOk
endproc 

这不会修改现有的数据库,也不会修改表结构。但是,在插入您的新记录内容之前,它将尝试获得表上的锁。然后看看最低和最高ID,你必须分析数据,找出为什么有些是负数和正数,并更新我在上面代码中的“占位符”条件。最后,解锁表格。

如果这是有意义的,很好,如果你需要调整,让我知道,我会试着帮助你更多。

票数 0
EN
页面原文内容由Stack Overflow提供。腾讯云小微IT领域专用引擎提供翻译支持
原文链接:

https://stackoverflow.com/questions/17195045

复制
相关文章

相似问题

领券
问题归档专栏文章快讯文章归档关键词归档开发者手册归档开发者手册 Section 归档