如何使用Alt-Ergo执行以下SMT-LIB代码

Question

下面的SMT-LIB代码在Z3，MathSat和CVC4中运行没有问题，但它不能在Alt-Ergo中运行，请让我知道发生了什么，非常感谢：

(set-logic QF_UF)
(set-option :incremental true)
(set-option :produce-models true)
(declare-fun m () Bool)
(declare-fun p () Bool)
(declare-fun b () Bool)
(declare-fun c () Bool)
(declare-fun r () Bool)
(declare-fun al () Bool)
(declare-fun all () Bool)
(declare-fun la () Bool)
(declare-fun lal () Bool)
(declare-fun g () Bool)
(declare-fun a () Bool)
(define-fun conjecture () Bool
(and (= (and (not r) c) m) (= p m) (= b m) (= c (not g)) 
     (= (and (not al) (not all)) r) (= (and la b) al) 
     (= (or al la lal) all) (= (and (not g) p a) la) 
     (= (and (not g) (or la a)) lal)))
(push 1)
(assert (and conjecture (= a false) (= g false)))
(check-sat)
(get-model)
(pop 1)
(push 1)
(assert (and conjecture (= a false) (= g true)))
(check-sat)
(get-model)
(pop 1)
(push 1)
(assert (and conjecture (= a true) (= g true)))
(check-sat)
(get-model)
(pop 1)
(push 1)
(assert (and conjecture (= a true) (= g false)))
(check-sat)
(get-model)

Answer 1

目前，Alt-Ergo不提供对SMT-2格式的完全支持。特别是，无法识别命令get-model。

此外，push和pop命令将被忽略。这就是为什么Alt-Ergo在给定的代码上会说sat，unsat，...，unsat (当get-model被移除时)。