从cmd打开“打开”-dialogbox

Question

我想知道我是否可以从cmd打开“打开”-dialogbox，这样我就可以用它来选择要打开的正确文件。(我已经知道如何直接从cmd打开文件，但这不是我感兴趣的)

目前，我正在做一个使用程序(例如program.exe)的项目。这个程序需要一个模型文件(例如modelfile.mod)。我通过编写: program.exe modelfile.mod来执行CMD中的程序，它可以工作。我有许多不同名称的模型文件，但程序文件总是具有相同的名称。不是每次我需要执行程序时都写入CMD，我想创建一个批处理，在其中我可以选择我想要执行的modfile，然后它将使用所选的modfile作为输入来执行程序。

因此，我需要知道如何从cmd打开“打开”的-dialogbox，以及如何获得所选文件的名称，以便在执行程序时使用。

Answer 1

如果你已经安装了PowerShell，你可以这样做：

@echo off
setlocal
set ps_cmd=powershell "Add-Type -AssemblyName System.windows.forms|Out-Null;$f=New-Object System.Windows.Forms.OpenFileDialog;$f.Filter='Model Files (*.mod)|*.mod|All files (*.*)|*.*';$f.showHelp=$true;$f.ShowDialog()|Out-Null;$f.FileName"

for /f "delims=" %%I in ('%ps_cmd%') do set "filename=%%I"

if defined filename (
    echo You chose %filename%
) else (
    echo You didn't choose squat!
)

goto :EOF

或者，如果您想要分解powershell cmdlet以便于维护：

@echo off
setlocal
set "ps=Add-Type -AssemblyName System.windows.forms | Out-Null;"
set "ps=%ps% $f=New-Object System.Windows.Forms.OpenFileDialog;"
set "ps=%ps% $f.Filter='Model Files (*.mod)|*.mod|All files (*.*)|*.*';"
set "ps=%ps% $f.showHelp=$true;"
set "ps=%ps% $f.ShowDialog() | Out-Null;"
set "ps=%ps% $f.FileName"

for /f "delims=" %%I in ('powershell "%ps%"') do set "filename=%%I"

if defined filename (
    echo You chose %filename%
) else (
    echo You didn't choose squat!
)

goto :EOF

(从Just Tinkering Blog那里毫不留情地窃取了PowerShell命令。)有关可以设置的其他属性，如Title和InitialDirectory，请参阅OpenFileDialog Class文档。