rebol2 vid应用程序中的请求日期

Question

谁能告诉我为什么下面的代码不能工作？它应该在加载时设置字段中的日期，然后允许通过单击字段来更改日期。我在linux上使用的是rebol/view 2.7.8。实际上，我想这段代码在几年前我使用MS Windows的时候就可以用了，但由于某种原因在linux下就不行了。

drl

    rebol []
    trace true
    out: layout [
        style dater txt bold right [trans-date/date: copy (form now/date)] 48x24
        dater "T-Date:" trans-date: field 80x24 (form now/date) feel [
            engage: func [face action event][
                if action = 'up [
                    lv-dat: request-date/date/offset (now/date) 450x375
                    if lv-dat <> none [
                        trans-date/text: form lv-dat
                        show trans-date
                    ]
                ]
            ]
            show trans-date
        ]
    ]
    view out  

Answer 1

以下是您的代码的经过清理的版本：

Rebol []

out: layout compose/deep [
    style dater txt bold right 48x24
    dater "T-Date:"
    trans-date: field 80x24 (form now/date) feel [
        engage: func [face action event][
            if action = 'up [
                lv-dat: request-date/date/offset (now/date) 450x375
                if lv-dat [
                    face/text: form lv-dat
                    show face
                ]
            ]
        ]
    ]
]
view out

主要问题是在调用layout之前，缺少用于计算paren表达式的compose/deep调用。但是，这种方法不是初始化face属性常用方法，您应该将初始化代码放在VID块的do部分中，如下所示：

Rebol []

out: layout [
    style dater txt bold right 48x24
    dater "T-Date:"
    trans-date: field 80x24 feel [
        engage: func [face action event][
            if action = 'up [
                lv-dat: request-date/date/offset now/date 450x375
                if lv-dat [
                    face/text: form lv-dat
                    show face
                ]
            ]
        ]
    ]
    do [trans-date/text: form now/date]
]
view out

希望这能有所帮助。