命令行安装MSI花费的时间太长

Question

由于某些原因，尝试通过命令行安装msi可执行文件需要花费太长时间，或者永远不会完成。该程序是windows的未签名主题，允许您在windows上运行不受支持的主题。可从此处获得：Download

我正在尝试使用以下命令安装64位版本：

start /wait "UxStyle Core x64.msi"

整个批处理文件如下所示：

@echo off

net stop uxsms

IF "%PROCESSOR_ARCHITECTURE%" == "AMD64" call :install64
IF "%PROCESSOR_ARCHITECTURE%" == "x86" call :install32

IF ERRORLEVEL 1 goto :UxStyleErr

takeown /f "%WINDIR%\Resources\Themes\Aero\aero.msstyles" 
icacls "%WINDIR%\Resources\Themes\Aero\aero.msstyles" /grant %USERNAME%:F"
ren "%WINDIR%\Resources\Themes\Aero\aero.msstyles" aero.msstyles.original
copy /y aero.msstyles "%WINDIR%\Resources\Themes\Aero\"

net start uxsms

echo Installation completed. Press any key to reboot or close this dialog if you want to restart later.
pause
shutdown /r /t 0
goto :eof

:install64
start /wait "UxStyle Core x64.msi"
goto :eof

:install32
start /wait "UxStyle Core x86.msi"
goto :eof

:UxStyleErr
echo An error occured while installing UxStyle Core. Installation will now quit.
pause
goto :eof

我做错了什么？

Answer 1

我建议直接调用msiexec.exe，而不是使用start /wait来启动.msi文件。您还可以生成一个日志文件，它将帮助您诊断哪里出了问题。因此，我将修改您的start /wait命令，使其如下所示：

msiexec /i "UxStyle Core x64.msi" /l*v x64_installlog.txt

您可以将/passive或/quiet添加到命令中，以分别显示进度条或完全没有UI的运行。

Answer 2

请阅读：

Msiexec (command-line options)

看起来您缺少/QB或/QB开关，无法在不进行交互的情况下运行。还可以考虑添加REBOOT=R，以防止它们的MSI执行任何意外的重启。