使用gen-class的clojure宏不会创建注释

Question

我正在尝试编写一个clojure宏，它将用于在编译时生成多个Java类。我发现，当我在宏外调用gen-class时，可以向类添加注释。但是，当我尝试在宏内使用gen-class时，编译后的类没有注释。

我把我的问题归结为这个例子：

(gen-class
  :name ^{Deprecated true} Test1
  :prefix Test1-
  :methods [[^{Deprecated true} getValue [] Integer]])

(defn Test1-getValue [] 42)

(defmacro create-test-class [name x]
  (let [prefix (str name "-")]
    `(do
      (gen-class
         :name ~(with-meta name {Deprecated true})
         :prefix ~(symbol prefix)
         :methods [[~(with-meta 'getValue {Deprecated true}) [] Integer]])
      (defn ~(symbol (str prefix "getValue")) [] ~x))))

(create-test-class Test2 56)

当我编译这个文件时，它创建了一个Test1.class和Test2.class -我用Eclipse检查了这两个类，发现Test1同时有类级和方法级的@Deprecated注解，但是Test2.class没有注解。当我使用宏扩展时，看起来好像我的Test2.class应该被注释：

user=> (set! *print-meta* true)
true
user=> (macroexpand '(create-test-class Test2 56))
(do (clojure.core/gen-class :name ^{java.lang.Deprecated true} Test2 :prefix Test2- :methods [[^{java.lang.Deprecated true} getValue [] java.lang.Integer]]) (user/defn Test2-getValue [] 56)) 

我在这里做错了什么？

Answer 1

Meikel Brandmeyer在这里回答了这个问题：

https://groups.google.com/forum/#!topic/clojure/Ee1bVwcUT-c

“在宏中引用注释。(使用-meta名称`{Deprecated true})。请注意反标记。”

下面是工作宏：

(defmacro create-test-class [name x]
  (let [prefix (str name "-")]
    `(do
      (gen-class
         :name ~(with-meta name `{Deprecated true})
         :prefix ~(symbol prefix)
         :methods [[~(with-meta 'getValue `{Deprecated true}) [] Integer]])
      (defn ~(symbol (str prefix "getValue")) [] ~x))))