是否强制刷新影片剪辑？

Question

我有一个非常简单的代码片段，就像这样；

loadingMc.visible = true;
trace("ok");
// send photo to server
loadingMc.visible = false;

发送照片需要3-5秒，但影片剪辑仅在过程的最后一秒可见。在进程开始时，我可以在输出中看到"ok“消息。所以我假设问题不是重新绘制电影剪辑。有没有在进程开始前强制重绘的选项？

更新:发送到服务器部分；

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
});

function savePicToServer(bmd:BitmapData):void
{   
    var jpgEncoder:JPGEncoder = new JPGEncoder(85);
    var jpgStream:ByteArray = jpgEncoder.encode(bmd);

    var loader:URLLoader = new URLLoader();
    configureListeners(loader);
    var header:URLRequestHeader = new URLRequestHeader("Content-type", "application/octet-stream");
    var request:URLRequest = new URLRequest("http://localhost/test/upload.php?key=prvkey");
    request.requestHeaders.push(header);
    request.method = URLRequestMethod.POST;
    request.data = jpgStream;
    loader.load(request);
}

在完整事件中；

loadingText.visible = false;

Answer 1

编辑

仅仅通过阅读你的代码，我不明白为什么这不应该工作-但是FP有时会做一些奇怪的事情。

在类似的情况下，我使用setTimeout()来强制播放器延迟后续操作，并允许屏幕刷新：

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    setTimeout( doSave, 10 );
});

private function doSave() : void {
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
}

如果这仍然不起作用，也许更长的超时时间可以解决这个问题-但通常情况下，10ms应该足以刷新屏幕。

编辑

另一种方法是添加和删除ENTER_FRAME侦听器，以确保帧确实被刷新：

upload.addEventListener(MouseEvent.CLICK, function(evt:MouseEvent):void{
    loadingText.visible = true;
    trace("ok");
    addEventListener( Event.ENTER_FRAME, onNextFrame );
});

private function onNextFrame( ev:Event ) : void {
    removeEventListener( Event.ENTER_FRAME, onNextFrame );
    doSave();
}

private function doSave() : void {
    var bmd:BitmapData = new BitmapData(1024,768,true,0);
    bmd.draw(imageArea);
    savePicToServer(bmd);
}