dcc32警告UnloadProcs.pas(59)：函数'GetType‘的W1035返回值可能未定义

Question

有一种数据类型

type
TDataTypeId = (DataTypeId_String, DataTypeId_SmallInt, DataTypeId_Integer, DataTypeId_Word,
               DataTypeId_Boolean, DataTypeId_Float, DataTypeId_Currency,
               DataTypeId_BCD, DataTypeId_FmtBCD, DataTypeId_Date,
               DataTypeId_Time, DataTypeId_DateTime, DataTypeId_TimeStamp,
               DataTypeId_Bytes, DataTypeId_VarBytes, DataTypeId_Blob,
               DataTypeId_Memo, DataTypeId_Graphic, DataTypeId_fmtMemo,
               DataTypeId_FixedChar, DataTypeId_WideChar, DataTypeId_LargeInt,
               DataTypeId_Array, DataTypeId_FixedWideChar, DataTypeId_WideMemo);

有一个函数，它接受包含此类型的值之一的行，返回此值

Function GetType(str: string): TDataTypeId;
var
typeidx: TDataTypeId;
typestr: string;
begin
for typeidx := Low(TDataTypeID) to High(TDataTypeID) do
 begin
  typestr:=GetEnumName(TypeInfo(TDataTypeId),Ord(typeidx));
  typestr:=Copy(typestr, 12, length(typestr)-11);
  //Memo.Lines.Add(typestr+'\n');
  if (AnsiCompareStr(str, typestr)=0) then
     Result:=typeidx
 end;
 end;

因此，会有一个程序集

[dcc32 Warning] UnloadProcs.pas(59): W1035 Return value of function 'GetType' might be undefined

如何转换没有出现警告的函数？

Answer 1

编译器警告是准确的。如果If语句的计算结果永远不会为True，因为找不到匹配项，则循环不会将其赋值给Result。然后函数退出，不赋值。

您的选择：

1. 在循环完成后为Result赋值，表示找不到匹配项。
2. 在循环完成后引发异常。

我还建议您在分配Result之后立即执行exit。当你找到答案后，继续循环是没有意义的。

我可能会这样写这个函数：

Function GetType(str: string): TDataTypeId;
var
  typestr: string;
begin
  for Result := low(Result) to high(Result) do
  begin
    typestr := GetEnumName(TypeInfo(TDataTypeId),Ord(typeidx));
    typestr := Copy(typestr, 12, length(typestr)-11);
    if AnsiSameStr(str, typestr) then
      exit;
  end;
  raise EEnumNotFound.CreateFmt('Enum not found: %s', [str]);
end; 

注意，Result变量用作循环变量。这是惯用的，其好处是减少了声明的局部变量的数量。

我同意您可以使用GetEnumValue更有效地解决您的问题，但我想向您展示如何以惯用的方式处理编译器警告。

Answer 2

关于在这样的循环中使用result的一般方法，下面是您可以如何编写函数的代码：

Function GetType(const str: string): TDataTypeId;
var
typestr: string;
begin
 for result := Low(TDataTypeID) to High(TDataTypeID) do
 begin
  typestr:=GetEnumName(TypeInfo(TDataTypeId),Ord(result));
  typestr:=Copy(typestr, 12, length(typestr)-11);
  //Memo.Lines.Add(typestr+'\n');
  if (AnsiCompareStr(str, typestr)=0) then
     exit; // if found, returns result value
 end;
 result := DataTypeId_String; // returns STRING type by default
end;

这是仅有的可以在循环范围之外使用循环变量的情况之一。生成的代码是正确的，并且经过优化。

我认为您应该更好地定义一个专用的TDataTypeId项，比如DataTypeId_Unknown，或者如果找不到它就引发一个异常。

Answer 3

其他人已经解释了这个警告，但更好的实现例程应该是这样的：

uses
  TypInfo, ConvUtils;

Function GetType(str: string): TDataTypeId;
var idx: Integer;
begin
  idx := GetEnumValue(TypeInfo(TDataTypeId), 'DataTypeId_'+str);
  if(idx <> -1)then Result := TDataTypeId(idx)
  else RaiseConversionError('Unknown typeID name: '+str);
end;

也就是说，不需要遍历所有枚举值并将它们作为字符串进行比较，而是使用GetEnumValue函数。