以最快的方式生成随机字符串

Question

我目前使用的是：

(defvar my-charset
  (eval-when-compile
    (concat (number-sequence 48 57) (number-sequence 65 90) (number-sequence 97 122)))
  "Char set in terms of number list.")
(defvar my-charset-length
  (eval-when-compile
    (length (concat (number-sequence 48 57) (number-sequence 65 90) (number-sequence 97 122))))
  "Length of my-charset.")

(defun my-generate-string (&optional max-length min-length)
  "Generate a random string."
  (let (string)
    (dotimes (_i (+ (random (- (or max-length 10) (or min-length 5) -1)) (or min-length 5)))
      (push (aref my-charset (random my-charset-length)) string))
    (concat string)))

有什么方法可以让它更快吗？

或者其他更快生成字符串的方法？

Answer 1

通过更有效地使用数据(和控制)结构，可以获得较小的性能增益。

(defconst our-charset "0123456789ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz")
(defconst our-charset-length (length our-charset))

(defun my-generate-string (&optional max-length min-length)
  "Generate a random string."
  (let (string)
    (dotimes (_i (+ (random (- (or max-length 10) (or min-length 5) -1)) (or min-length 5)))
      (push (aref our-charset (random our-charset-length)) string))
    (concat string)))

(defun our-generate-string (&optional max-length min-length)
  (let* ((max-length (or max-length 10))
         (min-length (or min-length 5))
         (length (+ min-length (random (- max-length min-length -1))))
         (string (make-string length ?0)))
    (dotimes (i length string)
      (aset string i
            (aref our-charset (random our-charset-length))))))

(defmacro measure-time (&rest body)
  `(let ((time (current-time)))
     ,@body
     (float-time (time-since time))))

(/
 (apply #'+
        (mapcar
         (lambda (ignore) (measure-time (my-generate-string 1000 999)))
         (number-sequence 0 999)))
 1000)
;; 0.0018966329990000002

(/
 (apply #'+
        (mapcar
         (lambda (ignore) (measure-time (our-generate-string 1000 999)))
         (number-sequence 0 999)))
 1000)
;; 0.0009833975549999997

根据硬件和随机性的不同，您的结果可能会有所不同，但our-generate-string应该更快。

您可能还想稍微调整一下调用约定。

(defun our-randomized-string (charset length)
  (let ((charset-length (length charset))
        (string (make-string length ?0)))
    (dotimes (i length string)
      (aset string i
            (aref charset (random charset-length))))))

(/
 (apply #'+
        (mapcar
         (lambda (ignore) (measure-time (our-randomized-string our-charset 1000)))
         (number-sequence 0 999)))
 1000)
 ;; 0.0009300809320000015

请注意，our-randomized-string不一定比our-generate-string快，但能够在函数外部修复参数，而不是在函数内部确定参数，这最终可能是一个好处。在这个版本中，字符集的交换也比在另一个版本中更容易。