我使用了GPUImage框架来实现类似于Instagram应用程序的模糊效果,在Instagram应用程序中,我制作了一个视图,用于从图片库中获取图片,然后在其上放置效果。
其中一个效果是选择性模糊效果,其中只有一小部分图像是清晰的,其余的是模糊的。GPUImageGaussianSelectiveBlurFilter选择图像的圆形部分不进行模糊处理。
我怎样才能改变这一点,使锐化区域变成矩形?
发布于 2013-01-29 08:04:17
因为Gill的答案并不完全正确,而且似乎有人一遍又一遍地问这个问题,所以我将澄清我上面的评论。
默认情况下,选择性模糊的片段着色器具有以下代码:
varying highp vec2 textureCoordinate;
varying highp vec2 textureCoordinate2;
uniform sampler2D inputImageTexture;
uniform sampler2D inputImageTexture2;
uniform lowp float excludeCircleRadius;
uniform lowp vec2 excludeCirclePoint;
uniform lowp float excludeBlurSize;
uniform highp float aspectRatio;
void main()
{
lowp vec4 sharpImageColor = texture2D(inputImageTexture, textureCoordinate);
lowp vec4 blurredImageColor = texture2D(inputImageTexture2, textureCoordinate2);
highp vec2 textureCoordinateToUse = vec2(textureCoordinate2.x, (textureCoordinate2.y * aspectRatio + 0.5 - 0.5 * aspectRatio));
highp float distanceFromCenter = distance(excludeCirclePoint, textureCoordinateToUse);
gl_FragColor = mix(sharpImageColor, blurredImageColor, smoothstep(excludeCircleRadius - excludeBlurSize, excludeCircleRadius, distanceFromCenter));
}此片段着色器从原始锐化图像和图像的高斯模糊版本中获取像素颜色值。然后,它根据最后三行的逻辑在这三行之间进行混合。
这些行中的第一行和第二行计算从您指定的中心坐标(默认情况下,图像死点的归一化坐标为(0.5,0.5) )到当前像素坐标的距离。当距离中心点的距离在两个阈值(内部透明圆和外部完全模糊圆)之间移动时,最后一条线使用smoothstep() GLSL函数在0和1之间平滑插值。然后,mix()运算符从smoothstep()获取输出,并在模糊和锐化颜色像素颜色之间淡入淡出,以生成适当的输出。
如果只想修改它以生成正方形而不是圆形,则需要调整片段着色器中的两条中心线,以使距离基于线性X或Y坐标,而不是距中心点的毕达哥拉斯距离。若要执行此操作,请将着色器更改为:
varying highp vec2 textureCoordinate;
varying highp vec2 textureCoordinate2;
uniform sampler2D inputImageTexture;
uniform sampler2D inputImageTexture2;
uniform lowp float excludeCircleRadius;
uniform lowp vec2 excludeCirclePoint;
uniform lowp float excludeBlurSize;
uniform highp float aspectRatio;
void main()
{
lowp vec4 sharpImageColor = texture2D(inputImageTexture, textureCoordinate);
lowp vec4 blurredImageColor = texture2D(inputImageTexture2, textureCoordinate2);
highp vec2 textureCoordinateToUse = vec2(textureCoordinate2.x, (textureCoordinate2.y * aspectRatio + 0.5 - 0.5 * aspectRatio));
textureCoordinateToUse = abs(excludeCirclePoint - textureCoordinateToUse);
highp float distanceFromCenter = max(textureCoordinateToUse.x, textureCoordinateToUse.y);
gl_FragColor = mix(sharpImageColor, blurredImageColor, smoothstep(excludeCircleRadius - excludeBlurSize, excludeCircleRadius, distanceFromCenter));
}Gill提到的线只是过滤器的输入参数,根本不能控制它的圆度。
我将进一步修改它以生成一个通用的矩形形状作为读者的练习,但这应该为您提供一个如何做到这一点的基础,并对此着色器中的线条做一些更多的解释。
发布于 2012-09-18 14:15:09
是不是...矩形效果的代码就在这两行中
blurFilter = [[GPUImageGaussianSelectiveBlurFilter alloc] init];
[(GPUImageGaussianSelectiveBlurFilter*)blurFilter setExcludeCircleRadius:80.0/320.0];
[(GPUImageGaussianSelectiveBlurFilter*)blurFilter setExcludeCirclePoint:CGPointMake(0.5f, 0.5f)];
// [(GPUImageGaussianSelectiveBlurFilter*)blurFilter setBlurSize:0.0f]; [(GPUImageGaussianSelectiveBlurFilter*)blurFilter setAspectRatio:0.0f];https://stackoverflow.com/questions/12257429
复制相似问题